Geometry::Primitive::Ellipse - An Ellipse

Geometry-Primitive documentation Contained in the Geometry-Primitive distribution.

Index

Code Index:

NAME

Top

Geometry::Primitive::Ellipse - An Ellipse

DESCRIPTION

Top

Geometry::Primitive::Ellipse represents an elliptical conic section.

SYNOPSIS

Top

  use Geometry::Primitive::Ellipse;

  my $ellipse = Geometry::Primitive::Ellipse->new(
      width => 15,
      height => 10
  );
  print $ellipse->area;

ATTRIBUTES

Top

height

Set/Get the height of this ellipse.

origin

Set/Get the origin of this ellipse.

width

Set/Get the width of this ellipse.

METHODS

Top

new

Creates a new Geometry::Primitive::Ellipse

area

Returns the area of this ellipse.

point_end

Gets the "end" point for this Ellipse. Same as point_start.

point_start

Get the point that "starts" this Ellipse. Returns the a point where the X coordinate is the Ellipse origin X and the origin Y + height / 2.

scale ($amount)

Returns a new ellipse whose radius is $amount times bigger than this one.

AUTHOR

Top

Cory Watson <gphat@cpan.org>

COPYRIGHT & LICENSE

Top

You can redistribute and/or modify this code under the same terms as Perl itself.

Geometry-Primitive documentation Contained in the Geometry-Primitive distribution. 
package Geometry::Primitive::Ellipse;
use Moose;
use MooseX::Storage;

use Math::Trig ':pi';

with qw(Geometry::Primitive::Shape MooseX::Clone MooseX::Storage::Deferred);

has 'height' => (
    is => 'rw',
    isa => 'Num',
    default => 0
);
has 'origin' => (
    is => 'rw',
    isa => 'Geometry::Primitive::Point',
    coerce => 1
);
has 'width' => (
    is => 'rw',
    isa => 'Num',
    default => 0
);

sub area {
    my ($self) = @_;
    return (pi * $self->width * $self->height) / 4;
};

sub point_end {
    my ($self) = @_;

    return $self->point_start;
}

sub point_start {
    my ($self) = @_;

    return Geometry::Primitive::Point->new(
        x => $self->origin->x,
        y => $self->origin->y - ($self->height / 2)
    );
}

sub scale {
    my ($self, $amount) = @_;

    return Geometry::Primitive::Ellipse->new(
        height => $self->height * $amount,
        width => $self->width * $amount
    );
}

__PACKAGE__->meta->make_immutable;

no Moose;
1;

__END__