GraphViz::ISA - Graphing class hierarchies at run-time

GraphViz-ISA documentation Contained in the GraphViz-ISA distribution.

Index

Code Index:

NAME

Top

GraphViz::ISA - Graphing class hierarchies at run-time

VERSION

Top

version 1.100860

SYNOPSIS

Top

  use GraphViz::ISA;
  my $p = Some::Class->new;

  my $g1 = GraphViz::ISA->new($p);
  print $g1->as_png;

  my $g2 = GraphViz::ISA->new('Some::Other::Module');
  print $g2->as_png;

DESCRIPTION

Top

This class constructs a graph showing the @ISA hierarchy (note: not object hierarchies) from a package name or a blessed scalar.

The methods described here are defined by this class; all other method calls are passed to the underlying GraphViz object:

METHODS

Top

new

This constructs the object itself and takes a parameter. The parameter can be either a package name or a scalar blessed into a package. It then calls isatree() and hands the result to graph(). Then it returns the newly constructed object.

isatree

Takes a package name as a parameter and traverses the indicated package's @ISA recursively, constructing a hash of hashes. If a package's @ISA is empty, it has an empty hashref as the value in the tree.

graph

Takes a tree previously constructed by isatree() and traverses it, creating nodes and edges as it goes along.

INSTALLATION

Top

See perlmodinstall for information and options on installing Perl modules.

BUGS AND LIMITATIONS

Top

No bugs have been reported.

Please report any bugs or feature requests through the web interface at http://rt.cpan.org/Public/Dist/Display.html?Name=GraphViz-ISA.

AVAILABILITY

Top

The latest version of this module is available from the Comprehensive Perl Archive Network (CPAN). Visit http://www.perl.com/CPAN/ to find a CPAN site near you, or see http://search.cpan.org/dist/GraphViz-ISA/.

The development version lives at http://github.com/hanekomu/GraphViz-ISA/. Instead of sending patches, please fork this project using the standard git and github infrastructure.

AUTHOR

Top

  Marcel Gruenauer <marcel@cpan.org>

COPYRIGHT AND LICENSE

Top

This software is copyright (c) 2001 by Marcel Gruenauer.

This is free software; you can redistribute it and/or modify it under the same terms as the Perl 5 programming language system itself.

GraphViz-ISA documentation Contained in the GraphViz-ISA distribution. 
use 5.008;
use strict;
use warnings;

package GraphViz::ISA;
our $VERSION = '1.100860';
# ABSTRACT: Graphing class hierarchies at run-time
use Carp;
use GraphViz;
our $AUTOLOAD;

sub new {
    my $this  = shift;
    my $class = ref($this) || $this;
    my $self  = {};
    bless $self, $class;
    $self->_init(@_);
    return $self;
}

sub _init {
    my ($self, $that) = @_;
    my $pkg = ref($that) || $that;
    $self->{g} = GraphViz->new();
    my $tree = { $pkg => $self->isatree($pkg) };
    $self->graph($tree);
}

sub isatree {
    my ($self, $pkg) = @_;
    no strict 'refs';
    my $isa = *{"$pkg\::ISA"}{ARRAY};
    return {} unless @$isa;
    my %out;
    for my $base (@$isa) {
        $out{$base} = $self->isatree($base);
    }
    return \%out;
}

sub graph {
    my ($self, $tree) = @_;
    return unless keys %$tree;
    for my $pkg (keys %$tree) {
        $self->{g}->add_node($pkg);
        $self->{g}->add_edge($_, $pkg) for keys %{ $tree->{$pkg} };
        $self->graph($tree->{$pkg});
    }
}

sub AUTOLOAD {
    my $self = shift;
    my $type = ref($self) or croak "$self is not an object";
    (my $name = $AUTOLOAD) =~ s/.*:://;
    return if $name =~ /DESTROY/;

    # hm, maybe GraphViz knows what to do with it...
    $self->{g}->$name(@_);
}
1;


__END__