HTML::FormFu::Constraint::DependOn - Multi-field Dependency Constraint

HTML-FormFu documentation Contained in the HTML-FormFu distribution.

Index

Code Index:

NAME

Top

HTML::FormFu::Constraint::DependOn - Multi-field Dependency Constraint

SYNOPSIS

Top

    type: DependOn
    name: foo
    others: bar

DESCRIPTION

Top

If a value is submitted for the field this constraint is attached to, then a value must also be submitted for all fields named in others in HTML::FormFu::Constraint::_others.

By default, if any of the named fields in others in HTML::FormFu::Constraint::_others are missing, an error will be attached to each missing field. This behaviour can be changed by setting any of attach_errors_to_base in HTML::FormFu::Constraint::_others, attach_errors_to_others in HTML::FormFu::Constraint::_others or attach_errors_to in HTML::FormFu::Constraint::_others.

This constraint doesn't honour the not() value.

SEE ALSO

Top

Is a sub-class of, and inherits methods from HTML::FormFu::Constraint::_others, HTML::FormFu::Constraint

HTML::FormFu

AUTHOR

Top

Carl Franks cfranks@cpan.org

LICENSE

Top

This library is free software, you can redistribute it and/or modify it under the same terms as Perl itself.

HTML-FormFu documentation Contained in the HTML-FormFu distribution. 
package HTML::FormFu::Constraint::DependOn;
use Moose;
extends 'HTML::FormFu::Constraint';

with 'HTML::FormFu::Role::Constraint::Others';

use HTML::FormFu::Util qw(
    DEBUG_CONSTRAINTS
    debug
);

sub process {
    my ( $self, $params ) = @_;

    # check when condition
    if ( !$self->_process_when($params) ) {
        DEBUG_CONSTRAINTS && debug('fail when() check - skipping constraint');
        return;
    }

    my $others = $self->others;
    if ( !defined $others ) {
        DEBUG_CONSTRAINTS && debug('no others() - skipping constraint');
        return;
    }

    my @names = ref $others ? @{$others} : ($others);
    my @failed;

    my $value = $self->get_nested_hash_value( $params, $self->nested_name );

    if ( !$self->constrain_value($value) ) {
        DEBUG_CONSTRAINTS && debug('no value - skipping constraint');
        return;
    }

    for my $name (@names) {
        my $value = $self->get_nested_hash_value( $params, $name );

        my $ok = 0;

        if ( ref $value eq 'ARRAY' ) {
            my @err = eval { $self->constrain_values( $value, $params ) };
            $ok = 1 if !@err && !$@;
        }
        else {
            $ok = eval { $self->constrain_value($value) };
            $ok = 0 if $@;
        }

        if ( !$ok ) {
            push @failed, $name;
        }
    }

    return $self->mk_errors( {
            pass => @failed ? 0 : 1,
            failed => \@failed,
            names  => [ $self->nested_name, @names ],
        } );
}

sub constrain_value {
    my ( $self, $value ) = @_;

    return 0 if !defined $value || $value eq '';

    return 1;
}

sub _localize_args {
    my ($self) = @_;

    return $self->parent->label;
}

__PACKAGE__->meta->make_immutable;

1;

__END__