HTML::FormFu::Constraint::File::MIME - MIME Type Constraint

HTML-FormFu documentation Contained in the HTML-FormFu distribution.

Index

Code Index:

NAME

Top

HTML::FormFu::Constraint::File::MIME - MIME Type Constraint

DESCRIPTION

Top

Constraint an uploaded file's MIME-type (Content-Type).

types is checked before regex.

METHODS

Top

types

Arguments: $mime_type

Arguments: \@mime_types

Optional.

Accepts a single MIME-type or an arrayref of MIME-types. Each is checked against the uploaded file's MIME-type (as given by the browser), and the constraint passes if any one of the given types matches.

regex

Arguments: $regex

Optional.

Accepts a string to be interpreted as a regex, and is checked against the uploaded files's MIME-type (as given by the browser).

The regex uses the /x flag, so that whitespace in the given string is ignored.

SEE ALSO

Top

Is a sub-class of, and inherits methods from HTML::FormFu::Constraint

HTML::FormFu

AUTHOR

Top

Carl Franks, cfranks@cpan.org

LICENSE

Top

This library is free software, you can redistribute it and/or modify it under the same terms as Perl itself.

HTML-FormFu documentation Contained in the HTML-FormFu distribution. 
package HTML::FormFu::Constraint::File::MIME;

use Moose;
extends 'HTML::FormFu::Constraint';

use List::MoreUtils qw( any );
use Scalar::Util qw( blessed );

has regex => ( is => 'rw', traits  => ['Chained'] );
has types => ( is => 'rw', traits  => ['Chained'] );

sub constrain_value {
    my ( $self, $value ) = @_;

    return 1 if !defined $value || $value eq '';

    return if !blessed($value) || !$value->isa('HTML::FormFu::Upload');

    my $input = $value->headers->content_type;
    my $types = $self->types;
    my $regex = $self->regex;

    if ( defined $types ) {
        if ( ref $types ne 'ARRAY' ) {
            $types = [$types];
        }

        return 1 if any { $input eq $_ } @$types;
    }

    if ( defined $regex ) {
        return $input =~ /$regex/x;
    }

    return;
}

__PACKAGE__->meta->make_immutable;

1;

__END__