HTML::FormFu::Transformer - Transformer Base Class

package HTML::FormFu::Transformer;

use Moose;
extends 'HTML::FormFu::Processor';

use HTML::FormFu::Exception::Transformer;
use Scalar::Util qw( blessed );
use Carp qw( croak );

sub process {
    my ( $self, $values, $params ) = @_;

    my $return;
    my @errors;

    if ( ref $values eq 'ARRAY' ) {
        my @return;
        for my $value (@$values) {
            my ($return) = eval { $self->transformer( $value, $params ) };

            if ($@) {
                push @errors, $self->return_error($@);
                push @return, undef;
            }
            else {
                push @return, $return;
            }
        }
        $return = \@return;
    }
    else {
        ($return) = eval { $self->transformer( $values, $params ) };

        if ($@) {
            push @errors, $self->return_error($@);
        }
    }

    $self->set_nested_hash_value( $params, $self->nested_name, $return );

    return (@errors);
}

sub return_error {
    my ( $self, $err ) = @_;

    if ( !blessed $err || !$err->isa('HTML::FormFu::Exception::Transformer') ) {
        $err = HTML::FormFu::Exception::Transformer->new;
    }

    return $err;
}

__PACKAGE__->meta->make_immutable;

1;

__END__