HTML::FormFu::Validator - Validator Base Class

HTML-FormFu documentation Contained in the HTML-FormFu distribution.

Index

Code Index:

NAME

Top

HTML::FormFu::Validator - Validator Base Class

SYNOPSIS

Top

DESCRIPTION

Top

METHODS

Top

CORE VALIDATORS

Top

BEST PRACTICES

Top

Try to avoid using callbacks if possible. Below is a more maintainable and reusable approach, which also keeps the code out of the controller.

A normal application's directory would contain:

    lib/HTML/FormFu/Constraint/MyApp/
    lib/HTML/FormFu/Validator/MyApp/
    lib/HTML/FormFu/Plugin/MyApp/
    etc.

Then, the form config file would just need:

    validator: 'MyApp::SomeValidator'

And the class would be something like this:

    package HTML::FormFu::Validator::MyApp::SomeValidator;
    use strict;
    use warnings;
    use base 'HTML::FormFu::Validator';

    sub validate_value {
        my ( $self, $value, $params ) = @_;

        my $c = $self->form->stash->{context};

        return 1 if $c->model('DBIC')->is_valid($value);

        # assuming you want to return a custom error message
        # which perhaps includes something retrieved from the model
        # otherwise, just return 0
        die HTML::FormFu::Exception::Validator->new({
            message => 'custom error message',
        });
    }

    1;
HTML::FormFu::Validator::Callback

AUTHOR

Top

Carl Franks, cfranks@cpan.org

LICENSE

Top

This library is free software, you can redistribute it and/or modify it under the same terms as Perl itself.

HTML-FormFu documentation Contained in the HTML-FormFu distribution. 
package HTML::FormFu::Validator;

use Moose;
extends 'HTML::FormFu::Processor';

use HTML::FormFu::Exception::Validator;
use Scalar::Util qw( reftype blessed );
use Carp qw( croak );

sub process {
    my ( $self, $params ) = @_;

    my $value = $self->get_nested_hash_value( $params, $self->nested_name );

    my @errors;

    if ( ( reftype( $value ) || '' ) eq 'ARRAY' ) {
        push @errors, eval { $self->validate_values( $value, $params ) };

        if ($@) {
            push @errors, $self->return_error($@);
        }
    }
    else {
        my $ok = eval { $self->validate_value( $value, $params ) };

        if ( $@ or !$ok ) {
            push @errors, $self->return_error($@);
        }
    }

    return @errors;
}

sub validate_values {
    my ( $self, $values, $params ) = @_;

    my @errors;

    for my $value (@$values) {
        my $ok = eval { $self->validate_value( $value, $params ) };

        if ( blessed $@ && $@->isa('HTML::FormFu::Exception::Validator') ) {
            push @errors, $@;
        }
        elsif ( $@ or !$ok ) {
            push @errors, HTML::FormFu::Exception::Validator->new;
        }
    }

    return @errors;
}

sub validate_value {
    croak "validate() should be overridden";
}

sub return_error {
    my ( $self, $err ) = @_;

    if ( !blessed $err || !$err->isa('HTML::FormFu::Exception::Validator') ) {
        $err = HTML::FormFu::Exception::Validator->new;
    }

    return $err;
}

__PACKAGE__->meta->make_immutable;

1;

__END__