HTML::Widget::Element::Radio - Radio Element

HTML-Widget documentation Contained in the HTML-Widget distribution.

Index

Code Index:

NAME

Top

HTML::Widget::Element::Radio - Radio Element

SYNOPSIS

Top

    my $e = $widget->element( 'Radio', 'foo' );
    $e->comment('(Required)');
    $e->label('Foo');
    $e->checked('checked');
    $e->value('bar');

DESCRIPTION

Top

Radio Element.

METHODS

Top

retain_default

If true, overrides the default behaviour, so that after a field is missing from the form submission, the xml output will contain the default value, rather than be empty.

new

containerize

SEE ALSO

Top

HTML::Widget::Element

AUTHOR

Top

Sebastian Riedel, sri@oook.de

LICENSE

Top

This library is free software, you can redistribute it and/or modify it under the same terms as Perl itself.

HTML-Widget documentation Contained in the HTML-Widget distribution. 
package HTML::Widget::Element::Radio;

use warnings;
use strict;
use base 'HTML::Widget::Element';
use NEXT;

__PACKAGE__->mk_accessors(qw/comment checked label value retain_default/);


sub new {
    shift->NEXT::new(@_)->value(1);
}


sub containerize {
    my ( $self, $w, $value, $errors, $args ) = @_;

    $value = ref $value eq 'ARRAY' ? shift @$value : $value;

    my $name = $self->name;

    # Search for multiple radio button with the same name
    my $multi = 0;
    my @elements = $w->find_elements( name => $name );

    for my $element (@elements) {
        next if $element eq $self;
        if ( $element->isa('HTML::Widget::Element::Radio') ) {
            $multi++;
        }
    }

    # Generate unique id
    if ($multi) {
        $w->{_stash}          ||= {};
        $w->{_stash}->{radio} ||= {};
        my $num = ++$w->{_stash}->{radio}->{$name};
        my $id = $self->id( $w, "$name\_$num" );
        $self->attributes->{id} ||= $id;
    }

    my $checked =
          defined $value
        ? ( defined $value && $value eq $self->value )
        ? 'checked'
        : undef
        : undef;

    if (   !defined $value
        && ( $self->retain_default || !$args->{submitted} )
        && $self->checked )
    {
        $checked = 'checked';
    }
    $value = $self->value;

    my $l = $self->mk_label( $w, $self->label, $self->comment, $errors );
    my $i = $self->mk_input( $w,
        { checked => $checked, type => 'radio', value => $value }, $errors );

    #$l ? ( $l->unshift_content($i) ) : ( $l = $i );
    my $e = $self->mk_error( $w, $errors );

    return $self->container( { element => $i, error => $e, label => $l } );
}


1;