Helios::TestService - Helios::Service subclass for testing purposes

package Helios::TestService;

use 5.008000;
use base qw( Helios::Service );
use strict;
use warnings;

use Error qw(:try);

use Helios::Error;			# pulls in all Helios::Error::* exception types
use Helios::Job;
use Helios::LogEntry::Levels qw(:all);

our $VERSION = '2.20';	# necessary for packaging purposes

#sub max_retries { return 2; }
#sub retry_delay { return 60; }

sub run {
	my $self = shift;
	my $job = shift;
	my $config = $self->getConfig();
	my $args = $job->getArgs();

	try {
		if ($self->debug) {
			print "--CONFIG PARAMS--\n";
			foreach (keys %$config) {
				print $_,'=',$config->{$_},"\n";
			}
		}

		if ($self->debug) { print "--JOB ARGUMENTS--\n"; }
		foreach my $arg (sort keys %$args) {
			if ($self->debug) { print uc($arg),'=',$args->{$arg},"|\n"; }
			$self->logMsg($job, LOG_DEBUG, "PARAM: $arg VALUE: ".$args->{$arg});
		}
		if ( defined($args->{failure}) ) {
			throw Helios::Error::Fatal("Artificially throwing error here");
		}
		# if your job completes successfully, you need to mark it was completed
		$self->completedJob($job);

	} catch Helios::Error::Warning with {
		# you can throw this in your "WORK" section to denote your job completed, but had warnings
		my $e = shift;
		$self->logMsg($job, LOG_WARNING, "Class $self WARNING: ".$e->text);
		$self->completedJob($job);
	} catch Helios::Error::Fatal with {
		# you can throw this in your "WORK" section to denote a job that failed
		# (it will be retried if you have defined max_retries() and this job hasn't been retried that many times)
		my $e = shift;
		$self->logMsg($job, LOG_ERR, "Class $self FAILED: ".$e->text);
		$self->failedJob($job, $e->text."(Class $self)",835);
	} otherwise {
		# "otherwise" catches unexpected errors that you perhaps didn't throw
		# usually you can mark the jobs as failed and have them retried
		my $e = shift;
		$self->logMsg($job, LOG_ERR, "Class $self FAILED with unexpected error: ".$e->text);
		$self->failedJob($job, $e->text."(Class $self)");
	};

}




1;
__END__