HtDig::Config - Perl extension for managing ht://Dig configuration files

  use HtDig::Config;
  my $htdig = new HtDig::Config('/opt/www/conf/configdig_sites.pl');
  $htdig->autodetect();
  while (my ($site_name, $path) = each %{$htdig->sites()}) {
    print "Site $site_name found at $path\n";
  }
  my $site = $htdig->sites("default");
  #etc.
  #See the HtDig::Site module for information on using the Site object
  #

package HtDig::Config;

use strict;
use vars qw($VERSION @ISA @EXPORT @EXPORT_OK $DEFAULT_CONFIG_LOCATION $DEFAULT_LOG_LOCATION $DEFAULT_HTDIG_LOCATION $sites $htdig_base_path $configdig_log_path);

use Data::Dumper;
use HtDig::Site;

require Exporter;
require AutoLoader;
$DEFAULT_CONFIG_LOCATION = '/opt/www/conf/configdig_sites.pl';
$DEFAULT_LOG_LOCATION = '/opt/www/logs';
$DEFAULT_HTDIG_LOCATION = '/opt/www';
@ISA = qw(Exporter AutoLoader);
@EXPORT = qw();
$VERSION = '1.01';

##
#Constructor for the Config object
##
sub new {
  my ($class, %attribs) = @_;
  my $self = {};
  $self->{path} = $attribs{conf_path} ? $attribs{conf_path} : $DEFAULT_CONFIG_LOCATION;

  #Autocreate allows us to create a conf that doesn't
  # already exist.
  if ($attribs{auto_create}) {
    unless (-f $self->{path}) {
      #I avoid using "touch" on the file to ensure cross-platform
      # compatibility, opting instead to just open it for writing.
      open(TMP,">" . $self->{path}) or die "Couldn't auto_create configuration file at " . $self->{path} . ": $!";
      print TMP "1;\n";
      close(TMP);
    }
  }
  else {
    unless (-f $self->{path}) {
        die "Configuation file " . $self->{path} . " missing and auto_create not set.";
    }
  }
  
  require $self->{path};

  #These next few items are in the $self->{path} file "required" in the
  # previous line
  $self->{sites} = $sites;
  $self->{configdig_log_path} = $configdig_log_path || $DEFAULT_LOG_LOCATION;
  $self->{htdig_base_path} = $htdig_base_path || $DEFAULT_HTDIG_LOCATION;

  return bless $self, $class;
}

##
#Persist the site registry to the file
##
sub save {
  my ($self) = @_;
  my $sites_file = Data::Dumper->Dump([$self->{sites}], ["sites"]);
  open(CONF,">" . $self->{path}) or die "Couldn't open " . $self->{path} . " for writing.";
  print CONF $sites_file;
  print CONF qq|\n\$configdig_log_path = '| . $self->{configdig_log_path} . qq|';\n|;   
  print CONF q|$htdig_base_path = '| . $self->{htdig_base_path} . qq|';\n|;
  close CONF;
}

##
#Get an array of site names
##
sub sites {
  my ($self) = @_;
  return keys %{$self->{sites}};
}

##
#Get a Site object by name
##
sub get_site {
  my ($self, $site) = @_;
  if ($site and defined($self->{sites}->{$site})) {
    return HtDig::Site->new(conf_path=>$self->{sites}->{$site}, site_name=>$site, config=>$self);
  }
  else {
    return undef;
  }
}

##
#Add a registration for a particular site configuration
##
sub add_site {
  my ($self, %attribs) = @_;
  my $site;
  eval('$site = new HtDig::Site(%attribs)');
  if ($@) {
    $self->{errstr} = "Couldn't register site: $@";
    return undef;
  }
  if ($site) {
    $self->{sites}->{$attribs{site_name}} = $attribs{conf_path};
  }
  return $site;
}

##
#Remove registration for a particular site configuration
##
sub delete_site {
  my ($self, %attribs) = @_;
  delete($self->{sites}->{$attribs{site_name}});
  return 1;
}

##
#Attempt to find htdig configurations in suggested
# and default locations
##
sub autodetect {
  my ($self, %attribs) = @_;
  my $configs_detected = 0;

  #Clear error string
  $self->{errstr} = '';

  #A couple of educated guesses
  # (using a hash automatically prevents duplicates)
  my %paths = (
	       "/opt/www/conf"=> 1,
	       "/usr/local/htdig/conf"=> 1,
	      );

  #The user's desired search paths
  for my $path (@{$attribs{paths}}) {
    $paths{$path} = 1;
  }

  #If they asked us to, use the search path to find htdig
  #If found, then deduce the install directory, and add to
  # list of searched paths
  if ($attribs{use_env_path}) {
    chomp(my $potential_path = `which htdig`);
    if (-f $potential_path) {
      my @path = split(/\//, $potential_path);
      my $config_path = join("/", @path[0..($#path-2)]) . "/conf";
      $paths{$config_path} = 1;
    }
  }

  #Next check each path
  for my $path (keys %paths) {
    $configs_detected += $self->_proc_dir($path);
  }
  return $configs_detected;
}

##
#Get error message using this method
##
sub errstr {
  my ($self) = @_;
  return $self->{errstr};
}

##
#Some private methods
##
sub _proc_dir {
  my ($self, $config_path) = @_;
  my $configs_detected = 0;
  return 0 if !-d $config_path;

  opendir(CONFDIR, $config_path);
  while (my $file = readdir(CONFDIR)) {
    next if ($file eq '.' or $file eq '..');
    if ($file =~ /\.conf$/) {
      my $autoname = $file eq "htdig.conf" ? "default" : $file;
      eval( qq|
	    	    \$self->add_site(site_name=>'$autoname', conf_path=>"$config_path/$file");
            |);
      if ($@) {
	$self->{errstr} .= $@ . $! . " when adding $config_path/$file\n";
      }
      else {
	++$configs_detected;
      }
    }
  }
  return $configs_detected;
}


# Autoload methods go after =cut, and are processed by the autosplit program.

1;
__END__