IO::Compress::Lzop - Write lzop files/buffers

IO-Compress-Lzop documentation Contained in the IO-Compress-Lzop distribution.

Index

Code Index:

NAME

Top

IO::Compress::Lzop - Write lzop files/buffers

SYNOPSIS

Top

    use IO::Compress::Lzop qw(lzop $LzopError) ;

    my $status = lzop $input => $output [,OPTS] 
        or die "lzop failed: $LzopError\n";

    my $z = new IO::Compress::Lzop $output [,OPTS]
        or die "lzop failed: $LzopError\n";

    $z->print($string);
    $z->printf($format, $string);
    $z->write($string);
    $z->syswrite($string [, $length, $offset]);
    $z->flush();
    $z->tell();
    $z->eof();
    $z->seek($position, $whence);
    $z->binmode();
    $z->fileno();
    $z->opened();
    $z->autoflush();
    $z->input_line_number();
    $z->newStream( [OPTS] );

    $z->close() ;

    $LzopError ;

    # IO::File mode

    print $z $string;
    printf $z $format, $string;
    tell $z
    eof $z
    seek $z, $position, $whence
    binmode $z
    fileno $z
    close $z ;

DESCRIPTION

Top

This module provides a Perl interface that allows writing lzop compressed data to files or buffer.

For reading lzop files/buffers, see the companion module IO::Uncompress::UnLzop.

Functional Interface

Top

A top-level function, lzop, is provided to carry out "one-shot" compression between buffers and/or files. For finer control over the compression process, see the "OO Interface" section.

    use IO::Compress::Lzop qw(lzop $LzopError) ;

    lzop $input => $output [,OPTS] 
        or die "lzop failed: $LzopError\n";

The functional interface needs Perl5.005 or better.

lzop $input => $output [, OPTS]

lzop expects at least two parameters, $input and $output.

The $input parameter

The parameter, $input, is used to define the source of the uncompressed data.

It can take one of the following forms:

A filename

If the $input parameter is a simple scalar, it is assumed to be a filename. This file will be opened for reading and the input data will be read from it.

A filehandle

If the $input parameter is a filehandle, the input data will be read from it. The string '-' can be used as an alias for standard input.

A scalar reference

If $input is a scalar reference, the input data will be read from $$input.

An array reference

If $input is an array reference, each element in the array must be a filename.

The input data will be read from each file in turn.

The complete array will be walked to ensure that it only contains valid filenames before any data is compressed.

An Input FileGlob string

If $input is a string that is delimited by the characters "<" and ">" lzop will assume that it is an input fileglob string. The input is the list of files that match the fileglob.

See File::GlobMapper for more details.

If the $input parameter is any other type, undef will be returned.

In addition, if $input is a simple filename, the default values for the Name and Time options will be sourced from that file.

If you do not want to use these defaults they can be overridden by explicitly setting the Name and Time options or by setting the Minimal parameter.

The $output parameter

The parameter $output is used to control the destination of the compressed data. This parameter can take one of these forms.

A filename

If the $output parameter is a simple scalar, it is assumed to be a filename. This file will be opened for writing and the compressed data will be written to it.

A filehandle

If the $output parameter is a filehandle, the compressed data will be written to it. The string '-' can be used as an alias for standard output.

A scalar reference

If $output is a scalar reference, the compressed data will be stored in $$output.

An Array Reference

If $output is an array reference, the compressed data will be pushed onto the array.

An Output FileGlob

If $output is a string that is delimited by the characters "<" and ">" lzop will assume that it is an output fileglob string. The output is the list of files that match the fileglob.

When $output is an fileglob string, $input must also be a fileglob string. Anything else is an error.

See File::GlobMapper for more details.

If the $output parameter is any other type, undef will be returned.

Notes

When $input maps to multiple files/buffers and $output is a single file/buffer the input files/buffers will each be stored in $output as a distinct entry.

Optional Parameters

Unless specified below, the optional parameters for lzop, OPTS, are the same as those used with the OO interface defined in the "Constructor Options" section below.

AutoClose => 0|1

This option applies to any input or output data streams to lzop that are filehandles.

If AutoClose is specified, and the value is true, it will result in all input and/or output filehandles being closed once lzop has completed.

This parameter defaults to 0.

BinModeIn => 0|1

When reading from a file or filehandle, set binmode before reading.

Defaults to 0.

Append => 0|1

The behaviour of this option is dependent on the type of output data stream.

* A Buffer

If Append is enabled, all compressed data will be append to the end of the output buffer. Otherwise the output buffer will be cleared before any compressed data is written to it.

* A Filename

If Append is enabled, the file will be opened in append mode. Otherwise the contents of the file, if any, will be truncated before any compressed data is written to it.

* A Filehandle

If Append is enabled, the filehandle will be positioned to the end of the file via a call to seek before any compressed data is written to it. Otherwise the file pointer will not be moved.

When Append is specified, and set to true, it will append all compressed data to the output data stream.

So when the output is a filehandle it will carry out a seek to the eof before writing any compressed data. If the output is a filename, it will be opened for appending. If the output is a buffer, all compressed data will be appended to the existing buffer.

Conversely when Append is not specified, or it is present and is set to false, it will operate as follows.

When the output is a filename, it will truncate the contents of the file before writing any compressed data. If the output is a filehandle its position will not be changed. If the output is a buffer, it will be wiped before any compressed data is output.

Defaults to 0.

Examples

To read the contents of the file file1.txt and write the compressed data to the file file1.txt.lzo.

    use strict ;
    use warnings ;
    use IO::Compress::Lzop qw(lzop $LzopError) ;

    my $input = "file1.txt";
    lzop $input => "$input.lzo"
        or die "lzop failed: $LzopError\n";

To read from an existing Perl filehandle, $input, and write the compressed data to a buffer, $buffer.

    use strict ;
    use warnings ;
    use IO::Compress::Lzop qw(lzop $LzopError) ;
    use IO::File ;

    my $input = new IO::File "<file1.txt"
        or die "Cannot open 'file1.txt': $!\n" ;
    my $buffer ;
    lzop $input => \$buffer 
        or die "lzop failed: $LzopError\n";

To compress all files in the directory "/my/home" that match "*.txt" and store the compressed data in the same directory

    use strict ;
    use warnings ;
    use IO::Compress::Lzop qw(lzop $LzopError) ;

    lzop '</my/home/*.txt>' => '<*.lzo>'
        or die "lzop failed: $LzopError\n";

and if you want to compress each file one at a time, this will do the trick

    use strict ;
    use warnings ;
    use IO::Compress::Lzop qw(lzop $LzopError) ;

    for my $input ( glob "/my/home/*.txt" )
    {
        my $output = "$input.lzo" ;
        lzop $input => $output 
            or die "Error compressing '$input': $LzopError\n";
    }

OO Interface

Top

Constructor

The format of the constructor for IO::Compress::Lzop is shown below

    my $z = new IO::Compress::Lzop $output [,OPTS]
        or die "IO::Compress::Lzop failed: $LzopError\n";

It returns an IO::Compress::Lzop object on success and undef on failure. The variable $LzopError will contain an error message on failure.

If you are running Perl 5.005 or better the object, $z, returned from IO::Compress::Lzop can be used exactly like an IO::File filehandle. This means that all normal output file operations can be carried out with $z. For example, to write to a compressed file/buffer you can use either of these forms

    $z->print("hello world\n");
    print $z "hello world\n";

The mandatory parameter $output is used to control the destination of the compressed data. This parameter can take one of these forms.

A filename

If the $output parameter is a simple scalar, it is assumed to be a filename. This file will be opened for writing and the compressed data will be written to it.

A filehandle

If the $output parameter is a filehandle, the compressed data will be written to it. The string '-' can be used as an alias for standard output.

A scalar reference

If $output is a scalar reference, the compressed data will be stored in $$output.

If the $output parameter is any other type, IO::Compress::Lzop::new will return undef.

Constructor Options

OPTS is any combination of the following options:

AutoClose => 0|1

This option is only valid when the $output parameter is a filehandle. If specified, and the value is true, it will result in the $output being closed once either the close method is called or the IO::Compress::Lzop object is destroyed.

This parameter defaults to 0.

Append => 0|1

Opens $output in append mode.

The behaviour of this option is dependent on the type of $output.

* A Buffer

If $output is a buffer and Append is enabled, all compressed data will be append to the end of $output. Otherwise $output will be cleared before any data is written to it.

* A Filename

If $output is a filename and Append is enabled, the file will be opened in append mode. Otherwise the contents of the file, if any, will be truncated before any compressed data is written to it.

* A Filehandle

If $output is a filehandle, the file pointer will be positioned to the end of the file via a call to seek before any compressed data is written to it. Otherwise the file pointer will not be moved.

This parameter defaults to 0.

Name => $string

Stores the contents of $string in the name field lzop header.

If Name is not specified, no gzip NAME field will be created.

Time => $number

Sets the Time field in the lzop header to $number.

This field defaults to the time the IO::Compress::Lzop object was created if this option is not specified.

Extra

TODO

BlockSize

TODO

Optimize

TODO

Minimal

Creates the smallest possible lzop file/buffer.

Disables the creation of all checksums.

No Name is stored.

TODO

Strict => 0|1

This is a placeholder option.

Examples

TODO

Methods

Top

print

Usage is

    $z->print($data)
    print $z $data

Compresses and outputs the contents of the $data parameter. This has the same behaviour as the print built-in.

Returns true if successful.

printf

Usage is

    $z->printf($format, $data)
    printf $z $format, $data

Compresses and outputs the contents of the $data parameter.

Returns true if successful.

syswrite

Usage is

    $z->syswrite $data
    $z->syswrite $data, $length
    $z->syswrite $data, $length, $offset

Compresses and outputs the contents of the $data parameter.

Returns the number of uncompressed bytes written, or undef if unsuccessful.

write

Usage is

    $z->write $data
    $z->write $data, $length
    $z->write $data, $length, $offset

Compresses and outputs the contents of the $data parameter.

Returns the number of uncompressed bytes written, or undef if unsuccessful.

flush

Usage is

    $z->flush;

Flushes any pending compressed data to the output file/buffer.

TODO

Returns true on success.

tell

Usage is

    $z->tell()
    tell $z

Returns the uncompressed file offset.

eof

Usage is

    $z->eof();
    eof($z);

Returns true if the close method has been called.

seek

    $z->seek($position, $whence);
    seek($z, $position, $whence);

Provides a sub-set of the seek functionality, with the restriction that it is only legal to seek forward in the output file/buffer. It is a fatal error to attempt to seek backward.

Empty parts of the file/buffer will have NULL (0x00) bytes written to them.

The $whence parameter takes one the usual values, namely SEEK_SET, SEEK_CUR or SEEK_END.

Returns 1 on success, 0 on failure.

binmode

Usage is

    $z->binmode
    binmode $z ;

This is a noop provided for completeness.

opened

    $z->opened()

Returns true if the object currently refers to a opened file/buffer.

autoflush

    my $prev = $z->autoflush()
    my $prev = $z->autoflush(EXPR)

If the $z object is associated with a file or a filehandle, this method returns the current autoflush setting for the underlying filehandle. If EXPR is present, and is non-zero, it will enable flushing after every write/print operation.

If $z is associated with a buffer, this method has no effect and always returns undef.

Note that the special variable $| cannot be used to set or retrieve the autoflush setting.

input_line_number

    $z->input_line_number()
    $z->input_line_number(EXPR)

This method always returns undef when compressing.

fileno

    $z->fileno()
    fileno($z)

If the $z object is associated with a file or a filehandle, fileno will return the underlying file descriptor. Once the close method is called fileno will return undef.

If the $z object is associated with a buffer, this method will return undef.

close

    $z->close() ;
    close $z ;

Flushes any pending compressed data and then closes the output file/buffer.

For most versions of Perl this method will be automatically invoked if the IO::Compress::Lzop object is destroyed (either explicitly or by the variable with the reference to the object going out of scope). The exceptions are Perl versions 5.005 through 5.00504 and 5.8.0. In these cases, the close method will be called automatically, but not until global destruction of all live objects when the program is terminating.

Therefore, if you want your scripts to be able to run on all versions of Perl, you should call close explicitly and not rely on automatic closing.

Returns true on success, otherwise 0.

If the AutoClose option has been enabled when the IO::Compress::Lzop object was created, and the object is associated with a file, the underlying file will also be closed.

newStream([OPTS])

Usage is

    $z->newStream( [OPTS] )

Closes the current compressed data stream and starts a new one.

OPTS consists of any of the the options that are available when creating the $z object.

See the "Constructor Options" section for more details.

Importing

Top

No symbolic constants are required by this IO::Compress::Lzop at present.

:all

Imports lzop and $LzopError. Same as doing this

    use IO::Compress::Lzop qw(lzop $LzopError) ;

EXAMPLES

Top

Apache::GZip Revisited

See IO::Compress::Lzop::FAQ (&quot;Apache::GZip Revisited&quot; in IO::Compress::Lzop::FAQ)

SEE ALSO

Top

Compress::Zlib, IO::Compress::Gzip, IO::Uncompress::Gunzip, IO::Compress::Deflate, IO::Uncompress::Inflate, IO::Compress::RawDeflate, IO::Uncompress::RawInflate, IO::Compress::Bzip2, IO::Uncompress::Bunzip2, IO::Compress::Lzma, IO::Uncompress::UnLzma, IO::Compress::Xz, IO::Uncompress::UnXz, IO::Uncompress::UnLzop, IO::Compress::Lzf, IO::Uncompress::UnLzf, IO::Uncompress::AnyInflate, IO::Uncompress::AnyUncompress

Compress::Zlib::FAQ (Compress::Zlib::FAQ)

File::GlobMapper, Archive::Zip, Archive::Tar, IO::Zlib

AUTHOR

Top

This module was written by Paul Marquess, pmqs@cpan.org.

MODIFICATION HISTORY

Top

See the Changes file.

COPYRIGHT AND LICENSE

Top

Copyright (c) 2005-2011 Paul Marquess. All rights reserved.

This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

IO-Compress-Lzop documentation Contained in the IO-Compress-Lzop distribution. 
package IO::Compress::Lzop ;

use strict ;
use warnings;
require Exporter ;
use bytes;

use IO::Compress::Base 2.037 ;

use IO::Compress::Base::Common  2.037 qw(createSelfTiedObject);
use IO::Compress::Adapter::LZO  2.037 ;
use Compress::LZO qw(crc32 adler32 LZO_VERSION);
use IO::Compress::Lzop::Constants  2.037 ;

our ($VERSION, @ISA, @EXPORT_OK, %EXPORT_TAGS, $LzopError);

$VERSION = '2.037';
$LzopError = '';

@ISA    = qw(Exporter IO::Compress::Base);
@EXPORT_OK = qw( $LzopError lzop ) ;
%EXPORT_TAGS = %IO::Compress::Base::EXPORT_TAGS ;
push @{ $EXPORT_TAGS{all} }, @EXPORT_OK ;
Exporter::export_ok_tags('all');

sub new
{
    my $class = shift ;

    my $obj = createSelfTiedObject($class, \$LzopError);
    return $obj->_create(undef, @_);
}

sub lzop
{
    my $obj = createSelfTiedObject(undef, \$LzopError);
    return $obj->_def(@_);
}

#sub ckSum
#{
#    my $self = shift ;
#    
#    return adler32($_[0]) if *$self->{LZOP}{Adler32} ;
#    return crc32($_[0]) if *$self->{LZOP}{CRRC32} ;
#    return '';
#}

sub mkHeader 
{
    my $self = shift ;
    my $param = shift ;

    my $filename = '';

    my $time = $param->value('Time') ;
    
    my $flags = F_OS_UNIX  ;
    if (! $param->value('Minimal')) {
        $flags |= F_ADLER32_D | F_ADLER32_C ;
        $filename = $param->value('Name') || '';
    }

    my $mode = 0 ;
    if ($param->value('Mode')) {
        $mode = $param->value('Mode');
    }

    my $xtr = '';
    if ($param->parsed('Extra')) {
        $flags |= F_H_EXTRA_FIELD ;

        my $extra = $param->value('Extra') ;
        $xtr .= pack 'N', length($extra)  ; # Extra Length
        $xtr .= $extra                    ; # Extra Data
        $xtr .= pack 'N', adler32($xtr)   ; # Extra CRC
    }
    
    my $hdr = '' ;

    $hdr .= pack 'n', 0x1010     ; # lzop Version 
    $hdr .= pack 'n', 0x1080     ; # LZO library version
    $hdr .= pack 'n', 0x1010     ; # lzop extract version
    $hdr .= pack 'C', 1          ; # Method
    $hdr .= pack 'C', 5          ; # Level
    $hdr .= pack 'N', $flags     ; # Flags

    $hdr .= pack 'N', $mode      ; # Mode
    $hdr .= pack 'N', $time      ; # Time
    $hdr .= pack 'N', 0          ; # GMDiff

    # Filename
    $hdr .= pack 'C', length $filename ; # filename length
    $hdr .= $filename ;

    # Header CRC
    $hdr .= pack 'N', adler32($hdr) ; # Header CRC

    # Extra
    $hdr .= $xtr;

    return SIGNATURE . $hdr;

}

sub ckParams
{
    my $self = shift ;
    my $got = shift;
    
    if (! $got->parsed('Time') ) {
        # Modification time defaults to now.
        $got->value('Time' => time) ;
    }

    #*$self->{LZOP}{Adler32} = ($got->value('??') ? 0 : 1) ;
    
    return 1 ;
}


sub mkComp
{
    my $self = shift ;
    my $got = shift ;

    my ($obj, $errstr, $errno) =  IO::Compress::Adapter::LZO::mkCompObject(
                                              $got->value('BlockSize'),
                                              $got->value('Optimize'),
                                              $got->value('Minimal'),
                                          );

    return $self->saveErrorString(undef, $errstr, $errno)
        if ! defined $obj;

    return $obj;    
                                          
}


sub mkTrailer
{
    my $self = shift ;
    return pack "N", 0 ;
}

sub mkFinalTrailer
{
    return '';
}

#sub newHeader
#{
#    my $self = shift ;
#    return '';
#}

sub getExtraParams
{
    my $self = shift ;

    use IO::Compress::Base::Common  2.037 qw(:Parse);
    
    return (
            'Name'      => [0, 1, Parse_any,       undef],
            'Time'      => [0, 1, Parse_any,       undef],
            'Mode'      => [0, 1, Parse_any,       0],
            'Extra'     => [0, 1, Parse_any,       undef],
            'Minimal'   => [0, 1, Parse_boolean,   0],
            'BlockSize' => [0, 1, Parse_unsigned,  BLOCK_SIZE],
            'Optimize'  => [0, 1, Parse_boolean,   1],

           # TODO 
           #   none
           #   crc32
           #   adler32
        );
    
}

sub getInverseClass
{
    return ('IO::Uncompress::UnLzop');
}

sub getFileInfo
{
    my $self = shift ;
    my $params = shift;
    my $filename = shift ;
    
    my ($defaultMode, $defaultTime) = (stat($filename))[2, 9] ;

    $params->value('Name' => $filename)
        if ! $params->parsed('Name') ;

    $params->value('Time' => $defaultTime) 
        if ! $params->parsed('Time') ;

    $params->value('Mode' => $defaultMode) 
        if ! $params->parsed('Mode') ;
}

1;

__END__