IPC::SharedMem - SysV Shared Memory IPC object class
Index
Code Index:
NAME
IPC::SharedMem - SysV Shared Memory IPC object class
SYNOPSIS
use IPC::SysV qw(IPC_PRIVATE S_IRUSR S_IWUSR);
use IPC::SharedMem;
$shm = IPC::SharedMem->new(IPC_PRIVATE, 8, S_IRWXU);
$shm->write(pack("S", 4711), 2, 2);
$data = $shm->read(0, 2);
$ds = $shm->stat;
$shm->remove;
DESCRIPTION
A class providing an object based interface to SysV IPC shared memory.
METHODS
- new ( KEY , SIZE , FLAGS )
-
Creates a new shared memory segment associated with KEY. A new
segment is created if
KEY is equal to IPC_PRIVATE KEY does not already have a shared memory segment associated
with it, and FLAGS & IPC_CREAT is true.
On creation of a new shared memory segment FLAGS is used to
set the permissions. Be careful not to set any flags that the
Sys V IPC implementation does not allow: in some systems setting
execute bits makes the operations fail.
- id
-
Returns the shared memory identifier.
- read ( POS, SIZE )
-
Read SIZE bytes from the shared memory segment at POS. Returns
the string read, or undef if there was an error. The return value
becomes tainted. See shmread.
- write ( STRING, POS, SIZE )
-
Write SIZE bytes to the shared memory segment at POS. Returns
true if successful, or false if there is an error. See shmwrite.
- remove
-
Remove the shared memory segment from the system or mark it as
removed as long as any processes are still attached to it.
- is_removed
-
Returns true if the shared memory segment has been removed or
marked for removal.
- stat
-
Returns an object of type IPC::SharedMem::stat which is a sub-class
of Class::Struct. It provides the following fields. For a description
of these fields see you system documentation.
uid
gid
cuid
cgid
mode
segsz
lpid
cpid
nattach
atime
dtime
ctime
- attach ( [FLAG] )
-
Permanently attach to the shared memory segment. When a IPC::SharedMem
object is attached, it will use memread and memwrite instead of
shmread and shmwrite for accessing the shared memory segment.
Returns true if successful, or false on error. See shmat.
- detach
-
Detach from the shared memory segment that previously has been attached
to. Returns true if successful, or false on error. See shmdt.
- addr
-
Returns the address of the shared memory that has been attached to in a
format suitable for use with pack('P'). Returns undef if the shared
memory has not been attached.
SEE ALSO
AUTHORS
Marcus Holland-Moritz <mhx@cpan.org>
COPYRIGHT
Version 2.x, Copyright (C) 2007-2010, Marcus Holland-Moritz.
Version 1.x, Copyright (c) 1997, Graham Barr.
This program is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.
################################################################################
#
# $Revision: 4 $
# $Author: mhx $
# $Date: 2010/03/07 16:01:42 +0100 $
#
################################################################################
#
# Version 2.x, Copyright (C) 2007-2010, Marcus Holland-Moritz <mhx@cpan.org>.
# Version 1.x, Copyright (C) 1997, Graham Barr <gbarr@pobox.com>.
#
# This program is free software; you can redistribute it and/or
# modify it under the same terms as Perl itself.
#
################################################################################
package IPC::SharedMem;
use IPC::SysV qw(IPC_STAT IPC_RMID shmat shmdt memread memwrite);
use strict;
use vars qw($VERSION);
use Carp;
$VERSION = do { my @r = '$Snapshot: /IPC-SysV/2.03 $' =~ /(\d+\.\d+(?:_\d+)?)/; @r ? $r[0] : '9.99' };
$VERSION = eval $VERSION;
# Figure out if we have support for native sized types
my $N = do { my $foo = eval { pack "L!", 0 }; $@ ? '' : '!' };
{
package IPC::SharedMem::stat;
use Class::Struct qw(struct);
struct 'IPC::SharedMem::stat' => [
uid => '$',
gid => '$',
cuid => '$',
cgid => '$',
mode => '$',
segsz => '$',
lpid => '$',
cpid => '$',
nattch => '$',
atime => '$',
dtime => '$',
ctime => '$',
];
}
sub new
{
@_ == 4 or croak 'IPC::SharedMem->new(KEY, SIZE, FLAGS)';
my($class, $key, $size, $flags) = @_;
my $id = shmget $key, $size, $flags;
return undef unless defined $id;
bless { _id => $id, _addr => undef, _isrm => 0 }, $class
}
sub id
{
my $self = shift;
$self->{_id};
}
sub addr
{
my $self = shift;
$self->{_addr};
}
sub stat
{
my $self = shift;
my $data = '';
shmctl $self->id, IPC_STAT, $data or return undef;
IPC::SharedMem::stat->new->unpack($data);
}
sub attach
{
@_ >= 1 && @_ <= 2 or croak '$shm->attach([FLAG])';
my($self, $flag) = @_;
defined $self->addr and return undef;
$self->{_addr} = shmat($self->id, undef, $flag || 0);
defined $self->addr;
}
sub detach
{
my $self = shift;
defined $self->addr or return undef;
my $rv = defined shmdt($self->addr);
undef $self->{_addr} if $rv;
$rv;
}
sub remove
{
my $self = shift;
return undef if $self->is_removed;
my $rv = shmctl $self->id, IPC_RMID, 0;
$self->{_isrm} = 1 if $rv;
return $rv;
}
sub is_removed
{
my $self = shift;
$self->{_isrm};
}
sub read
{
@_ == 3 or croak '$shm->read(POS, SIZE)';
my($self, $pos, $size) = @_;
my $buf = '';
if (defined $self->addr) {
memread($self->addr, $buf, $pos, $size) or return undef;
}
else {
shmread($self->id, $buf, $pos, $size) or return undef;
}
$buf;
}
sub write
{
@_ == 4 or croak '$shm->write(STRING, POS, SIZE)';
my($self, $str, $pos, $size) = @_;
if (defined $self->addr) {
return memwrite($self->addr, $str, $pos, $size);
}
else {
return shmwrite($self->id, $str, $pos, $size);
}
}
1;
__END__