Jifty::Plugin::Comment::Model::Comment - comments attached to anything

  # to customize...
  package App::Model::Comment;
  use base qw/ Jifty::Plugin::Comment::Model::Comment /;

  use Jifty::DBI::Schema;
  use App::Record schema {
      # Add a reference to the current user that creates this comment
      column by_user =>
          references App::Model::User,
          ;
  };

  # make it so that any logged user can comment, but anyone can view, except
  # that we don't really want everyone seeing all those personal bits...
  sub current_user_can {
      my $self = shift;
      my ($right, %args) = @_;

      if ($right eq 'create') {
          return 1 if $self->current_user->id;
      }

      if ($right eq 'read') {
          return $self->published
              unless $args{column} =~ /^ 
                  (?: email
                    | status
                    | ip_addr
                    | http_refer
                    | http_user_agent ) $/x;
      }

      # otherwise only superuser gets in
      return $self->SUPER::current_user_can(@_);
  }

use strict;
use warnings;

package Jifty::Plugin::Comment::Model::Comment;
use Jifty::DBI::Schema;

use constant CLASS_UUID => '7B703CCA-544E-11DC-9227-2E96D84604BE';

use Jifty::Record schema {
    column title =>
        type is 'text',
        label is 'Title',
        is mandatory,
        ;

    column body =>
        type is 'text',
        label is 'Body',
        is mandatory,
        render as 'Textarea',
        ;

    column created_on =>
        type is 'timestamp',
        label is 'Created on',
        filters are qw/ Jifty::DBI::Filter::DateTime /,
        ;

    column your_name =>
        type is 'text',
        label is 'Your name',
        is mandatory,
        ;

    column web_site =>
        type is 'text',
        label is 'Web site',
        ;

    column email =>
        type is 'text',
        label is 'Email address',
        ;

    column published =>
        type is 'boolean',
        label is 'Published?',
        is mandatory,
        default is 1,
        ;

    column status =>
        type is 'varchar(4)',
        label is 'Status',
        valid_values are qw/ spam ham /,
        default is 'ham',
        ;

    column ip_addr =>
        type is 'text',
        label is 'IP Address',
        ;

    column http_referer =>
        type is 'text',
        label is 'HTTP Referer',
        ;

    column http_user_agent =>
        type is 'text',
        label is 'HTTP User Agent',
        ;
};

use DateTime;
use HTML::Scrubber;

sub table { 'comment_comments' }

sub before_create {
    my $self = shift;
    my $args = shift;

    # Clean up stuff added by Jifty::Plugin::Comment::Action::CreateComment
    delete $args->{parent_class};
    delete $args->{parent_id};

    my $plugin   = Jifty->find_plugin('Jifty::Plugin::Comment');
    my $scrubber = $plugin->scrubber;

    # Store safe fields
    $args->{'title'}           = Jifty->web->escape($args->{'title'});
    $args->{'your_name'}       = Jifty->web->escape($args->{'your_name'});
    $args->{'web_site'}        = Jifty->web->escape($args->{'web_site'});
    $args->{'email'}           = Jifty->web->escape($args->{'email'});
    $args->{'body'}            = $scrubber->scrub($args->{'body'});

    $args->{'created_on'}      = DateTime->now;

    $args->{'ip_addr'}         = $ENV{'REMOTE_ADDR'};
    $args->{'http_user_agent'} = $ENV{'HTTP_USER_AGENT'};
    $args->{'http_referer'}    = $ENV{'HTTP_REFERER'};

    # Prep for Akismet check or stop
    my $akismet = $plugin->akismet or return 1;

    # Check to see if it's classified as spam
    my $verdict = $akismet->check(
        USER_IP              => $args->{'ip_addr'},
        USER_AGENT           => $args->{'http_user_agent'},
        REFERER              => $args->{'http_referer'},
        COMMENT_CONTENT      => $args->{'title'}."\n\n".$args->{'body'},
        COMMENT_AUTHOR       => $args->{'your_name'},
        COMMENT_AUTHOR_EMAIL => $args->{'email'},
        COMMENT_AUTHOR_URL   => $args->{'web_site'},
    );

    # I have no idea what it is... mark it spam just in case...
    # TODO the default no verdict action should configurable
    if (!$verdict) {
        $args->{published} = 0;
        $args->{status}    = 'spam';

        warn "Failed to determine whether new comment is spam or not.";
        return 1;
    }

    # Naughty, naughty... mark as spam
    if ($verdict eq 'true') {
        warn "A new comment is detected as spam.";

        $args->{published} = 0;
        $args->{status}    = 'spam';

        return 1;
    }

    # Excellent, post that ham
    else {
        $args->{published} = 1;
        $args->{status}    = 'ham';

        return 1;
    }
}

sub before_set_status {
    my $self = shift;
    my $args = shift;

    my $plugin  = Jifty->find_plugin('Jifty::Plugin::Comment');
    my $akismet = $plugin->akismet or return 1;

    my %akismet_report = (
        USER_IP              => $self->ip_addr,
        USER_AGENT           => $self->http_user_agent,
        REFERER              => $self->http_referer,
        COMMENT_CONTENT      => $self->title."\n\n".$self->body,
        COMMENT_AUTHOR       => $self->your_name,
        COMMENT_AUTHOR_EMAIL => $self->email,
        COMMENT_AUTHOR_URL   => $self->web_site,
    );

    if ($self->status eq 'spam' && $args->{value} eq 'ham') {
        if ($akismet->ham( %akismet_report )) {
            Jifty->log->info("Reported that comment ".$self->id." is HAM to Akismet.");
        }
        else {
            # Not the end of the world, just that Akismet doesn't know...
            Jifty->log->info("FAILED to report that comment ".$self->id." is HAM to Akismet.");
        }
    }

    elsif ($self->status eq 'ham' && $args->{value} eq 'spam') {
        if ($akismet->spam( %akismet_report )) {
            Jifty->log->info("Reported that comment ".$self->id." is SPAM to Akismet.");
        }
        else {
            # Not the end of the world, just that Akismet doesn't know...
            Jifty->log->info("FAILED to report that comment ".$self->id." is SPAM to Akismet.");
        }
    }

    return 1;
}

1;