Index

NAME
SYNOPSIS
DESCRIPTION
PORTAL OPTIONS
USING LEMONLDAP::NG::PORTAL FOR DEVELOPMENT
- * Lemonldap::NG::Portal::Simple: base module to build a portal,
- * Lemonldap::NG::Portal::Auth*: authentication modules that modify authentication scheme.
- * Lemonldap::NG::Portal::AuthLA: specific module to used Liberty-Alliance mechanisms to authenticate users
- * Lemonldap::NG::Portal::SharedConf: this module provide the ability to read portal configuration from a central database. It inherits from Lemonldap::NG::Portal::Simple. It's the more used module.
SEE ALSO
AUTHOR
BUG REPORT
DOWNLOAD
COPYRIGHT AND LICENSE

NAME

Lemonldap::NG::Portal - The authentication portal part of Lemonldap::NG Web-SSO system.

SYNOPSIS

  use Lemonldap::NG::Portal::SharedConf;
  my $portal = new Lemonldap::NG::Portal::SharedConf (
         configStorage => {
            type          => 'DBI',
            dbiChain      => "dbi:mysql:database=lmSessions;host=1.2.3.4",
            dbiUser       => "lemon",
            dbiPassword   => "pass",
         },
         # Activate SOAP service
         Soap           => 1
        );




  if($portal->process()) {
      # Write here the menu with CGI methods. This page is displayed ONLY IF
      # the user was not redirected here by a Lemonldap::NG::Handler,
      # else, the process sub redirect the user to the initial requested URI.
      print $portal->header('text/html; charset=utf8'); # DON'T FORGET THIS (see L<CGI(3)>)
      print "...";

      # or redirect the user to the menu
      print $portal->redirect( -uri => 'https://portal/menu');

      # You can also add a "Logout" link:
      print "<a href=\"$ENV{SCRIPT_NAME}?logout=1\">";
  }
  else {
      # Write here the html form used to authenticate with CGI methods.
      # $portal->error returns the error message if authentication failed
      # You can force the language in error like this :
      #   print $portal->error('fr')
      # Warning: by defaut, input names are "user" and "password"
      print $portal->header('text/html; charset=utf8'); # DON'T FORGET THIS (see L<CGI(3)>)
      print "<html> ...";
      print '<form method="POST">';
      # In your form, the following value is required for redirection
      print '<input type="hidden" name="url" value="'.$portal->param('url').'">';
      # Next, login and password
      print 'Login : <input name="user"><br>';
      print 'Password : <input name="password" type="password" autocomplete="off"><br>';
      print '<input type=submit value="OK">';
      print '</form>';
  }

SOAP mode authentication (client) :

  #!/usr/bin/perl -l

  use SOAP::Lite;
  use Data::Dumper;

  my $soap =
    SOAP::Lite->proxy('http://auth.example.com/')
    ->uri('urn:/Lemonldap::NG::Common::CGI::SOAPService');
  my $r = $soap->getCookies( 'user', 'password' );

  # Catch SOAP errors
  if ( $r->fault ) {
      print STDERR "SOAP Error: " . $r->fault->{faultstring};
  }
  else {
      my $res = $r->result();

      # If authentication failed, display error
      if ( $res->{error} ) {
          print STDERR "Error: " . $soap->error( 'fr', $res->{error} )->result();
      }

      # print session-ID
      else {
          print "Cookie: lemonldap=" . $res->{cookies}->{lemonldap};
      }
  }

DESCRIPTION

Lemonldap::NG is a modular Web-SSO based on Apache::Session modules. It simplifies the build of a protected area with a few changes in the application.

It manages both authentication and authorization and provides headers for accounting. So you can have a full AAA protection for your web space as described below.

The portal part inherits from CGI so yo can use it both with Apache 1 and 2 and use all CGI features.

Authentication, Autorization, Accounting

Authentication

If a user isn't authenticated and attempts to connect to an area protected by a Lemonldap::NG compatible handler, he is redirected to a portal. The portal authenticates user with a ldap bind by default, but you can also use another authentication sheme like using x509 user certificates (see Lemonldap::NG::Portal::AuthSSL for more).

Lemonldap::NG use session cookies generated by Apache::Session so as secure as a 128-bit random cookie. You may use the securedCookie options of Lemonldap::NG::Portal to avoid session hijacking if all your protected sites use https.

You have to manage life of sessions by yourself since Lemonldap::NG knows nothing about the Apache::Session module you've choosed, but it's very easy using a simple cron script because Lemonldap::NG::Portal stores the start time in the _utime field. The purgeCentralCache provided in example/ directory can help you to do it. By default, a session stay 10 minutes in the Handler local storage, so in the worth case, a user is authorized 10 minutes after he lost his rights.

Authorization

Authorization is controled only by handlers because the portal knows nothing about the way the user will choose. When configuring your Web-SSO, you have to:

* choose the ldap attributes you want to use to manage accounting and authorization (see exportedHeaders parameter in Lemonldap::NG::Portal documentation),
* create Perl expression to define user groups (using ldap attributes): optional, this mechanism is available with Lemonldap::NG::*::SharedConf modules,
* create an array foreach virtual host associating URI regular expressions and Perl expressions to use to grant access.

Example

Exported variables (in Lemonldap::NG::Portal, will be stored in configuration database):

  exportedVars => {
      cn            => "cn",
      departmentUID => "departmentUID",
      login         => "uid",
  },

User groups (stored in configuration database with Lemonldap::NG::Manager):

  groups => {
      group1 => '{ $departmentUID eq "unit1" or $login = "xavier.guimard" }',
      ...
  },

Area protection (stored in configuration database with Lemonldap::NG::Manager):

  locationRules => {
      www1.domain.com => {
          '^/protected/.*$' => '$groups =~ /\bgroup1\b/',
          default           => 'accept',
      },
      www2.domain.com => {
          '^/site/.*$' => '$uid eq "xavier.guimard" or $groups =~ /\bgroup2\b/',
          '^/(js|css)' => 'accept',
          default      => 'deny',
      },
  },

Performance

You can use Perl expressions as complicated as you want and you can use all the exported LDAP attributes (and create your own attributes: see examples in Lemonldap::NG::Portal distribution) both in groups evaluations and area protections (you just have to call them with a "$").

You have to be careful when choosing your expressions:

* groups are evaluated each time a user is redirected to the portal,
* locationRules are evaluated for each request.

It is also recommended to use the groups mechanism to avoid having to evaluate a long expression at each HTTP request:

  locationRules => {
      www1.domain.com => {
          '^/protected/.*$' => '$groups =~ /\bgroup1\b/',
      },
  },

You can also use ldap filters in groups parameter, or Perl expression or mixed expressions. Perl expressions has to be enclosed with {}:

* group1 => '(|(uid=xavier.guimard)(ou=unit1))'
* group1 => '{$uid eq "xavier.guimard" or $ou eq "unit1"}'
* group1 => '(|(uid=xavier.guimard){$ou eq "unit1"})'

It is also recommended to use Perl expressions to avoid requiering the LDAP server more than 2 times per authentication.

Accounting

Logging portal access

Lemonldap::NG::Portal doesn't log anything by default, but it's easy to overload log method for normal portal access or using error method to know what was wrong if process method has failed.

Logging application access

Because an handler knows nothing about the protected application, it can't do more than logging URL. As Apache does this fine, Lemonldap::NG::Handler gives it the name to used in logs. The whatToTrace parameters indicates which variable Apache has to use ($uid by default).

The real accounting has to be done by the application itself which knows the result of SQL transaction for example.

Lemonldap::NG can export http headers either using a proxy or protecting directly the application. By default, the User-Auth field is used but you can change it using the exportedHeaders parameters (stored in the configuration database). This parameters contains an associative array:

* keys are the names of the chosen headers
* values are perl expressions where you can use user datas stored in the global store by calling them $<varname>.

Example:

  exportedHeaders => {
      www1.domain.com => {
          'Auth-User' => '$uid',
          'Unit'      => '$ou',
      },
      www2.domain.com => {
          'Authorization' => '"Basic ".encode_base64($employeeNumber.":dummy")',
      },
  }

Storage systems

Lemonldap::NG use 3 levels of cache for authenticated users:

* an Apache::Session::* module choosed with the globalStorage parameter (completed with globalglobalStorageOptions) and used by lemonldap::NG::Portal to store authenticated user parameters,
* a Cache::Cache module choosed with the localStorage parameter (completed with localStorageOptions and used to share authenticated users between Apache's threads or processus and of course between virtual hosts,
* Lemonldap::NG variables: if the same user use the same thread or processus a second time, no request are needed to grant or refuse access. This is very efficient with HTTP/1.1 Keep-Alive system.

So the number of request to the central storage is limited to 1 per user each 10 minutes.

Lemonldap::NG is very fast, but you can increase performance using a Cache::Cache module that does not use disk access.

Logout system

Lemonldap::NG provides a single logout system: you can use it by adding a link to the portal with "logout=1" parameter (See Synopsis) and/or by configuring Handler to intercept some URL directly in the manager interface and/or in Apache configuration file (See Lemonldap::NG::Handler). The logout system:

* delete session in the global session storage,
* replace Lemonldap::NG cookie by '',
* delete handler caches only if logout action was started from a protected application and only in the current Apache server. So in other servers, session is still in cache for 10 minutes maximum if the user was connected on it in the last 10 minutes.

Existing sessions

By default, when a user tries to connect to the portal with a valid cookie, the portal proposes a new authentication. This behaviour can be change easily by changing existingSession sub :

  use Lemonldap::NG::Portal::SharedConf qw(:all);

  my $portal = Lemonldap::NG::Portal::SharedConf->new ( {
                existingSession => sub {PE_DONE},
                configStorage => ...
                ...
  });

PORTAL OPTIONS

Manager options

All options here can be set both in the manager interface and in the constructor ($portal->new()). Local arguments have the precedence on arguments set by the manager.

* ldapPort: tcp port used by ldap server.
* ldapBase: base of the ldap directory.
* managerDn: dn to used to connect to ldap server. By default, anonymous bind is used.
* managerPassword: password to used to connect to ldap server. By default, anonymous bind is used.
* securedCookie : set it to 1 if you want to protect user cookies.
* cookieName : name of the cookie used by Lemonldap::NG (lemonldap by default).
* domain : cookie domain. You may have to give it else the SSO will work only on your server.
* globalStorage : required: Apache::Session library to used to store session information.
* globalStorageOptions : parameters to bind to Apache::Session module
* locationRules : this parameter is used by Lemonldap::NG::Handler to read the rules. It can be set in the portal just to display protected sites by the function getProtectedSites.
* authentication: sheme to authenticate users (default: "ldap"). It can be set to:

Local options

Those options can not be set using the manager but have to be passed to the constructor (new()).

* configStorage (required for Lemonldap::NG::Portal::SharedConf) : describe how to find configuration generated by Lemonldap::NG::Manager. See Lemonldap::NG::Common::Conf for more
* caPath, caFile : if you use ldap+tls you can overwrite cafile or capath options with those parameters. This is useful if you use a shared configuration.
* ldapPpolicyControl : set it to 1 if you want to use LDAP Password Policy
* useLocalCachedConf : for each authentication, the portal process reads its configuration. With a shared configuration stored on a network and if the system has a heavy load and if you have a running Lemonldap::NG::Handler instance on the same server, you can used the configuration stored in the local cache but setting this parameter to 1.
* localStorage, localStorageOptions : if the above option is set to 1, you have to set the good values in those parameters. See Lemonldap::NG::Handler for the syntax.
* ldapGroupBase : this parameter can be used to store in the Lemonldap::NG groups system all the LDAP groups that contains the user. Set here the LDAP base of the LDAP groups. Example : "dmdName=groups,dc=example,dc=com".
* methodName : all method used by the process sub can be overloaded simply using an option that referenced a sub. See Lemonldap::NG::Portal::Simple for more.

CAS authentication options :

* CAS_url, CAS_CAFile, CAS_loginUrl, CAS_validationUrl : see Lemonldap::NG::Portal::AuthCAS for more

Liberty-Alliance authentication options :

* laSp, laIdpsFile, laStorage, laLdapLoginAttribute, localStorage, localStorageOptions, laDebug : see Lemonldap::NG::Portal::AuthLA for more.

SSL authentication options :

* SSLRequire : if set to 0, both SSL and LDAP authentication are used. If set to 1, client certificate are required.
* SSLVar : the name of the SSL variable to read. Default to SSL_CLIENT_S_DN_Email.
* SSLLDAPField : the LDAP attribute that correspond to SSLVar.

USING LEMONLDAP::NG::PORTAL FOR DEVELOPMENT

Lemonldap::NG::Portal provides different modules:

* Lemonldap::NG::Portal::Simple: base module to build a portal,
* Lemonldap::NG::Portal::Auth*: authentication modules that modify authentication scheme.
* Lemonldap::NG::Portal::AuthLA: specific module to used Liberty-Alliance mechanisms to authenticate users
* Lemonldap::NG::Portal::SharedConf: this module provide the ability to read portal configuration from a central database. It inherits from Lemonldap::NG::Portal::Simple. It's the more used module.

AUTHOR

Xavier Guimard, <x.guimard@free.fr>

BUG REPORT

Use OW2 system to report bug or ask for features: http://jira.ow2.org

DOWNLOAD

Lemonldap::NG is available at http://forge.objectweb.org/project/showfiles.php?group_id=274

COPYRIGHT AND LICENSE

This library is free software; you can redistribute it and/or modify it under the same terms as Perl itself, either Perl version 5.10.0 or, at your option, any later version of Perl 5 you may have available.

Lemonldap::NG::Portal - The authentication portal part of Lemonldap::NG Web-SSO