List::Filter::Storage::MEM - filter storage in memory

   use List::Filter::Storage::MEM;
   my $ffpsm = List::Filter::Storage::MEM->new();

   # This is a plugin, not intended for direct use.
   # See: List:Filter:Storage

package List::Filter::Storage::MEM;
# use base qw( Class::Base );
use base qw( List::Filter::StorageBase );

use 5.8.0;
use strict;
use warnings;
use Carp;
use Data::Dumper;
use Hash::Util qw( lock_keys unlock_keys );

our $VERSION = '0.01';

# Note: "new" (inherited from Class::Base)
# calls the following "init" routine automatically.

sub init {
  my $self = shift;
  my $args = shift;
  unlock_keys( %{ $self } );

  $self->SUPER::init( $args );  # uncomment if this is a child class

  my $filter_data = $args->{connect_to} || {};
  $self->set_filter_data( $filter_data );

  lock_keys( %{ $self } );
  return $self;
}

sub save {
  my $self    = shift;
  my $filter = shift;

  # convert $filter object into a data structure,

  my $filter_name   = $filter->name;

  my $method         = $filter->method;
  my $description    = $filter->description;
  my $terms          = $filter->terms;
  my $modifiers      = $filter->modifiers;

  my $filter_href = {  method       => $method,
                       description  => $description,
                       terms        => $terms,
                       modifiers    => $modifiers,
                     };

  # add it to the internal stash (replaces any existing one of same name)
  my $filter_data = $self->filter_data;
  $filter_data->{ $filter_name } = $filter_href;

  return $filter;
}

# Note: this is *identical* to the code in (the original) YAML.pm
sub lookup {
  my $self = shift;
  my $name = shift;

  my $filter_data = $self->filter_data;

  my $filter;
  if ( my $filter_href = $filter_data->{ $name } ) {

    # convert this data into a filter object.
    my $terms        = $filter_href->{terms};
    my $method       = $filter_href->{method};
    my $description  = $filter_href->{description};
    my $modifiers    = $filter_href->{modifiers};

    my $filter_class = $self->define_filter_class;
    $filter = $filter_class->new(
      { name         => $name,
        terms        => $terms,
        method       => $method,
        description  => $description,
        modifiers    => $modifiers,
      } );

  }
  return $filter;
}

sub list_filters {
  my $self = shift;
  my $filter_data = $self->filter_data;
  my @names = keys (%{ $filter_data });
  return \@names;
}

sub filter_data {
  my $self = shift;
  my $filter_data = $self->extra->{ filter_data };

  return $filter_data;
}

sub set_filter_data {
  my $self = shift;
  my $filter_data = shift;
  $self->extra->{ filter_data } = $filter_data;
  return $filter_data;
}


1;