Log::Dispatch::Email - Base class for objects that send log messages via email

Log-Dispatch documentation Contained in the Log-Dispatch distribution.

Index

Code Index:

NAME

Top

Log::Dispatch::Email - Base class for objects that send log messages via email

VERSION

Top

version 2.29

SYNOPSIS

Top

  package Log::Dispatch::Email::MySender;

  use Log::Dispatch::Email;
  use base qw( Log::Dispatch::Email );

  sub send_email {
      my $self = shift;
      my %p    = @_;

      # Send email somehow.  Message is in $p{message}
  }

DESCRIPTION

Top

This module should be used as a base class to implement Log::Dispatch::* objects that send their log messages via email. Implementing a subclass simply requires the code shown in the SYNOPSIS with a real implementation of the send_email() method.

CONSTRUCTOR

Top

The constructor takes the following parameters in addition to the standard parameters documented in Log::Dispatch::Output:

* subject ($)

The subject of the email messages which are sent. Defaults to "$0: log email"

* to ($ or \@)

Either a string or a list reference of strings containing email addresses. Required.

* from ($)

A string containing an email address. This is optional and may not work with all mail sending methods.

* buffered (0 or 1)

This determines whether the object sends one email per message it is given or whether it stores them up and sends them all at once. The default is to buffer messages.

METHODS

Top

* send_email(%p)

This is the method that must be subclassed. For now the only parameter in the hash is 'message'.

* flush

If the object is buffered, then this method will call the send_email() method to send the contents of the buffer and then clear the buffer.

* DESTROY

On destruction, the object will call flush() to send any pending email.

AUTHOR

Top

Dave Rolsky <autarch@urth.org>

COPYRIGHT AND LICENSE

Top

This software is Copyright (c) 2011 by Dave Rolsky.

This is free software, licensed under:

  The Artistic License 2.0 (GPL Compatible)
Log-Dispatch documentation Contained in the Log-Dispatch distribution. 
package Log::Dispatch::Email;
BEGIN {
  $Log::Dispatch::Email::VERSION = '2.29';
}

use strict;
use warnings;

use Log::Dispatch::Output;

use base qw( Log::Dispatch::Output );

use Params::Validate qw(validate SCALAR ARRAYREF BOOLEAN);
Params::Validate::validation_options( allow_extra => 1 );

# need to untaint this value
my ($program) = $0 =~ /(.+)/;

sub new {
    my $proto = shift;
    my $class = ref $proto || $proto;

    my %p = validate(
        @_, {
            subject => {
                type    => SCALAR,
                default => "$program: log email"
            },
            to   => { type => SCALAR | ARRAYREF },
            from => {
                type     => SCALAR,
                optional => 1
            },
            buffered => {
                type    => BOOLEAN,
                default => 1
            },
        }
    );

    my $self = bless {}, $class;

    $self->_basic_init(%p);

    $self->{subject} = $p{subject} || "$0: log email";
    $self->{to} = ref $p{to} ? $p{to} : [ $p{to} ];
    $self->{from} = $p{from};

    # Default to buffered for obvious reasons!
    $self->{buffered} = $p{buffered};

    $self->{buffer} = [] if $self->{buffered};

    return $self;
}

sub log_message {
    my $self = shift;
    my %p    = @_;

    if ( $self->{buffered} ) {
        push @{ $self->{buffer} }, $p{message};
    }
    else {
        $self->send_email(@_);
    }
}

sub send_email {
    my $self  = shift;
    my $class = ref $self;

    die "The send_email method must be overridden in the $class subclass";
}

sub flush {
    my $self = shift;

    if ( $self->{buffered} && @{ $self->{buffer} } ) {
        my $message = join '', @{ $self->{buffer} };

        $self->send_email( message => $message );
        $self->{buffer} = [];
    }
}

sub DESTROY {
    my $self = shift;

    $self->flush;
}

1;

# ABSTRACT: Base class for objects that send log messages via email





__END__