Log::Log4perl::MDC - Mapped Diagnostic Context

Log-Log4perl documentation Contained in the Log-Log4perl distribution.

Index

Code Index:

NAME

Top

Log::Log4perl::MDC - Mapped Diagnostic Context

DESCRIPTION

Top

Log::Log4perl allows loggers to maintain global thread-specific data, called the Nested Diagnostic Context (NDC) and Mapped Diagnostic Context (MDC).

The MDC is a simple thread-specific hash table, in which the application can stuff values under certain keys and retrieve them later via the "%X{key}" placeholder in Log::Log4perl::Layout::PatternLayouts.

Log::Log4perl::MDC->put($key, $value);

Store a value $value under key $key in the map.

my $value = Log::Log4perl::MDC->get($key);

Retrieve the content of the map under the specified key. Typically done by %X{key} in Log::Log4perl::Layout::PatternLayout. If no value exists to the given key, undef is returned.

my $text = Log::Log4perl::MDC->remove();

Delete all entries from the map.

Log::Log4perl::MDC->get_context();

Returns a reference to the hash table.

Please note that all of the methods above are class methods, there's no instances of this class. Since the thread model in perl 5.8.0 is "no shared data unless explicetly requested" the data structures used are just global (and therefore thread-specific).

COPYRIGHT AND LICENSE

Top

Copyright 2002-2009 by Mike Schilli <m@perlmeister.com> and Kevin Goess <cpan@goess.org>.

This library is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

Log-Log4perl documentation Contained in the Log-Log4perl distribution. 
##################################################
package Log::Log4perl::MDC;
##################################################

use 5.006;
use strict;
use warnings;

our %MDC_HASH = ();

###########################################
sub get {
###########################################
    my($class, $key) = @_;

    if($class ne __PACKAGE__) {
        # Somebody called us with Log::Log4perl::MDC::get($key)
        $key = $class;
    }

    if(exists $MDC_HASH{$key}) {
        return $MDC_HASH{$key};
    } else {
        return undef;
    }
}

###########################################
sub put {
###########################################
    my($class, $key, $value) = @_;

    if($class ne __PACKAGE__) {
        # Somebody called us with Log::Log4perl::MDC::put($key, $value)
        $value = $key;
        $key   = $class;
    }

    $MDC_HASH{$key} = $value;
}

###########################################
sub remove {
###########################################
    %MDC_HASH = ();

    1;
}

###########################################
sub get_context {
###########################################
    return \%MDC_HASH;
}

1;

__END__