Maypole::Plugin::LinkTools - convenient link construction

Maypole-Plugin-LinkTools documentation Contained in the Maypole-Plugin-LinkTools distribution.

Index

Code Index:

NAME

Top

Maypole::Plugin::LinkTools - convenient link construction

SYNOPSIS

Top

    use Maypole::Application qw( LinkTools );

    #...

    print $request->maybe_link_view( $thing );

    print $request->maybe_many_link_views( @things );

    print $request->link( table      => $table,
                          action     => $action,        # called 'command' in the original link template
                          additional => $additional,    # optional - generally an object ID
                          label      => $label,
                          );

    print $request->make_path( table      => $table,
                               action     => $action,        # called 'command' in the original link template
                               additional => $additional,    # optional - generally an object ID
                               );

DESCRIPTION

Top

Provides convenient replacements for the link and maybe_link_view templates, and a new maybe_many_link_views method.

Centralises all path manipulation, so that a new URI scheme can be implemented site-wide by overriding just two methods (Maypole::parse_path() and Maypole::Plugin::LinkTools::make_path()).

For ease of use with the Template Toolkit, make_path, link and link_view will also accept a hashref of arguments. For example:

    print $request->make_path({ table      => $table,
                                action     => $action,
                                additional => $additional,
                             });

METHODS

Top

make_path( %args or \%args )

This is the counterpart to Maypole::parse_path. It generates a path to use in links, form actions etc. To implement your own path scheme, just override this method and parse_path.

    %args = ( table      => $table,
              action     => $action,        # called 'command' in the original link template
              additional => $additional,    # optional - generally an object ID
              );

id can be used as an alternative key to additional.

Returns a link, calling make_path to generate the path. 

    %args = ( table      => $table,
              action     => $action,        # called 'command' in the original link template
              additional => $additional,    # optional - generally an object ID
              label      => $label,
              );

The table can be omitted and defaults to that of the request's model. id can be used as an alternative key to additional.

Build a link to the view action of the given item. If passed a Maypole request object, builds a link to its view action. 

    print $request->link_view( $maypole_request );

    print $request->link_view( table      => $table,
                               label      => $label,
                               additional => $id,
                               );

Returns stringified $thing unless it isa Maypole::Model::Base object, in which case a link to the view template for the object is returned.

Runs multiple items through maybe_link_view, returning a list.

AUTHOR

Top

David Baird, <cpan@riverside-cms.co.uk>

BUGS

Top

Please report any bugs or feature requests to bug-maypole-plugin-linktools@rt.cpan.org, or through the web interface at http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Maypole-Plugin-LinkTools. I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.

ACKNOWLEDGEMENTS

Top

COPYRIGHT & LICENSE

Top

Copyright 2005 David Baird, All Rights Reserved.

This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

Maypole-Plugin-LinkTools documentation Contained in the Maypole-Plugin-LinkTools distribution. 
package Maypole::Plugin::LinkTools;

use warnings;
use strict;

our $VERSION = '0.21';


# TODO:
# C<$additional> can be a string, an arrayref, or a hashref. An arrayref is expanded into extra 
# path elements, whereas a hashref is translated into a query string. 
sub make_path
{
    my $r = shift;
    my %args = (@_ == 1 && ref $_[0] && ref $_[0] eq 'HASH') ? %{$_[0]} : @_;

    do { die "no $_" unless $args{ $_ } } for qw( table
                                                  action
                                                  );    

    my $base = $r->config->uri_base;
    $base = '' if $base eq '/';

    $args{additional} ||= $args{id};
    my $add = $args{additional} ? "/$args{additional}" : '';
    
    return sprintf '%s/%s/%s%s', $base, $args{table}, $args{action}, $add;
}
        

sub link
{
    my $r = shift;
    my %args = (@_ == 1 && ref $_[0] && ref $_[0] eq 'HASH') ? %{$_[0]} : @_;
    
    $args{table} ||= $r->model_class->table;
    $args{label} ||= '...'; # in case a stringify column is left empty
    
    foreach my $key ( qw( table action ) )
    { 
        die sprintf "link: no %s (got table: %s action: %s label: %s)",
            $key, $args{table} || '', $args{action} || '', $args{label} || '' 
                unless $args{ $key };
    } 
    
    my $path = $r->make_path( %args );
    
    return sprintf '<a href="%s">%s</a>', $path, $args{label};
}


sub link_view
{
    my $r = shift;
    
    my %args;
    
    if ( @_ == 1 )
    {
        die "single argument to link_view() must be a reference (got $_[0])" unless ref $_[0];
    
        if ( ref $_[0] eq 'HASH' )
        {
            %args = %{ $_[0] };
        }
        elsif ( UNIVERSAL::isa( $_[0], 'Maypole::Model::Base' ) )
        {
            my $object = shift;
            
            my $str = ''.$object;
            warn sprintf "%s (id: %s) object has no data for stringification", ref($object), $object->id unless $str;
            $str ||= '...';
            
            %args = ( table      => $object->table,
                      additional => $object->id,
                      label      => $str,
                      );
        }
        else
        {
            die "unsuitable single argument to link_view (got $_[0]) - need hashref or Maypole/CDBI object";
        }
    }
    else
    {
        %args = @_;
    }
    
    return $r->link( %args, action => 'view' );
}


sub maybe_link_view
{
    my ( $r, $thing ) = @_; 
    
    if ( ref $thing and UNIVERSAL::isa( $thing, 'Maypole::Model::Base' ) )
    {
        return $r->link_view( $thing );
    }
    else
    {
        return ''.$thing;
    }    
}


# if the accessor is for a has_many relationship, it might return multiple items, which 
# would each be passed individually to maybe_link_view(), and then each would go in its 
# own column. Instead, we want a list of items to put in a single cell.
sub maybe_many_link_views
{
    my ( $r, @values ) = @_;
    
    return map { $r->maybe_link_view( $_ ) } @values;
}




1; # End of Maypole::Plugin::LinkTools