Module::Loaded - mark modules as loaded or unloaded

Module-Loaded documentation Contained in the Module-Loaded distribution.

Index

Code Index:

NAME

Top

Module::Loaded - mark modules as loaded or unloaded

SYNOPSIS

Top

    use Module::Loaded;

    $bool = mark_as_loaded('Foo');   # Foo.pm is now marked as loaded
    $loc  = is_loaded('Foo');        # location of Foo.pm set to the 
                                     # loaders location
    eval "require 'Foo'";            # is now a no-op

    $bool = mark_as_unloaded('Foo'); # Foo.pm no longer marked as loaded
    eval "require 'Foo'";            # Will try to find Foo.pm in @INC

DESCRIPTION

Top

When testing applications, often you find yourself needing to provide functionality in your test environment that would usually be provided by external modules. Rather than munging the %INC by hand to mark these external modules as loaded, so they are not attempted to be loaded by perl, this module offers you a very simple way to mark modules as loaded and/or unloaded.

FUNCTIONS

Top

$bool = mark_as_loaded( PACKAGE );

Marks the package as loaded to perl. PACKAGE can be a bareword or string.

If the module is already loaded, mark_as_loaded will carp about this and tell you from where the PACKAGE has been loaded already.

$bool = mark_as_unloaded( PACKAGE );

Marks the package as unloaded to perl, which is the exact opposite of mark_as_loaded. PACKAGE can be a bareword or string.

If the module is already unloaded, mark_as_unloaded will carp about this and tell you the PACKAGE has been unloaded already.

$loc = is_loaded( PACKAGE );

is_loaded tells you if PACKAGE has been marked as loaded yet. PACKAGE can be a bareword or string.

It returns falls if PACKAGE has not been loaded yet and the location from where it is said to be loaded on success.

BUG REPORTS

Top

Please report bugs or other issues to <bug-module-loaded@rt.cpan.org<gt>.

AUTHOR

Top

This module by Jos Boumans <kane@cpan.org>.

COPYRIGHT

Top

This library is free software; you may redistribute and/or modify it under the same terms as Perl itself.

Module-Loaded documentation Contained in the Module-Loaded distribution. 
package Module::Loaded;

use strict;
use Carp qw[carp];

BEGIN { use base 'Exporter';
        use vars qw[@EXPORT $VERSION];
        
        $VERSION = '0.06';
        @EXPORT  = qw[mark_as_loaded mark_as_unloaded is_loaded];
}


sub mark_as_loaded (*) {
    my $pm      = shift;
    my $file    = __PACKAGE__->_pm_to_file( $pm ) or return;
    my $who     = [caller]->[1];
    
    my $where   = is_loaded( $pm );
    if ( defined $where ) {
        carp "'$pm' already marked as loaded ('$where')";
    
    } else {
        $INC{$file} = $who;
    }
    
    return 1;
}


sub mark_as_unloaded (*) { 
    my $pm      = shift;
    my $file    = __PACKAGE__->_pm_to_file( $pm ) or return;

    unless( defined is_loaded( $pm ) ) {
        carp "'$pm' already marked as unloaded";

    } else {
        delete $INC{ $file };
    }
    
    return 1;
}


sub is_loaded (*) { 
    my $pm      = shift;
    my $file    = __PACKAGE__->_pm_to_file( $pm ) or return;

    return $INC{$file} if exists $INC{$file};
    
    return;
}


sub _pm_to_file {
    my $pkg = shift;
    my $pm  = shift or return;
    
    my $file = join '/', split '::', $pm;
    $file .= '.pm';
    
    return $file;
}    


# Local variables:
# c-indentation-style: bsd
# c-basic-offset: 4
# indent-tabs-mode: nil
# End:
# vim: expandtab shiftwidth=4:

1;