Mojolicious::Command::Generate::LiteApp - Lite App Generator Command

Mojolicious documentation Contained in the Mojolicious distribution.

Index

Code Index:

NAME

Top

Mojolicious::Command::Generate::LiteApp - Lite App Generator Command

SYNOPSIS

Top

  use Mojolicious::Command::Generate::LiteApp;

  my $app = Mojolicious::Command::Generate::LiteApp->new;
  $app->run(@ARGV);

DESCRIPTION

Top

Mojolicious::Command::Generate::LiteApp is a application generator.

ATTRIBUTES

Top

Mojolicious::Command::Generate::LiteApp inherits all attributes from Mojo::Command and implements the following new ones.

description

  my $description = $app->description;
  $app            = $app->description('Foo!');

Short description of this command, used for the command list.

usage

  my $usage = $app->usage;
  $app      = $app->usage('Foo!');

Usage information for this command, used for the help screen.

METHODS

Top

Mojolicious::Command::Generate::LiteApp inherits all methods from Mojo::Command and implements the following new ones.

run

  $app->run(@ARGV);

Run this command.

SEE ALSO

Top

Mojolicious, Mojolicious::Guides, http://mojolicio.us.

Mojolicious documentation Contained in the Mojolicious distribution. 
package Mojolicious::Command::Generate::LiteApp;
use Mojo::Base 'Mojo::Command';

has description => <<'EOF';
Generate Mojolicious::Lite application.
EOF
has usage => <<"EOF";
usage: $0 generate lite_app [NAME]
EOF

# "As a scientist,
#  I can assure you that we did in fact evolve from filthy monkey-men."
sub run {
  my ($self, $name) = @_;
  $name ||= 'myapp.pl';
  $self->renderer->line_start('%%');
  $self->renderer->tag_start('<%%');
  $self->renderer->tag_end('%%>');
  $self->render_to_rel_file('liteapp', $name);
  $self->chmod_file($name, 0744);
}

1;
__DATA__
@@ liteapp
%% my $class = shift;
#!/usr/bin/env perl

use Mojolicious::Lite;

# Documentation browser under "/perldoc" (this plugin requires Perl 5.10)
plugin 'pod_renderer';

get '/welcome' => sub {
  my $self = shift;
  $self->render('index');
};

app->start;
<%%= '__DATA__' %%>

<%%= '@@ index.html.ep' %%>
% layout 'default';
% title 'Welcome';
Welcome to Mojolicious!

<%%= '@@ layouts/default.html.ep' %%>
<!doctype html><html>
  <head><title><%= title %></title></head>
  <body><%= content %></body>
</html>
__END__