Test::Mojo - Testing Mojo!

  use Test::More tests => 10;
  use Test::Mojo;

  my $t = Test::Mojo->new(app => 'MyApp');

  $t->get_ok('/welcome')
    ->status_is(200)
    ->content_like(qr/Hello!/, 'welcome message');

  $t->post_form_ok('/search', {title => 'Perl', author => 'taro'})
    ->status_is(200)
    ->content_like(qr/Perl.+taro/);

  $t->delete_ok('/something')
    ->status_is(200)
    ->header_is('X-Powered-By' => 'Mojolicious (Perl)')
    ->header_isnt('X-Bender' => 'Bite my shiny metal ass!');
    ->content_is('Hello world!');

Test::Mojo is a collection of testing helpers for everyone developing Mojo and Mojolicious applications.

Test::Mojo implements the following attributes.

  my $app = $t->app;
  $t      = $t->app(MyApp->new);

Application to be tested.

  my $tx = $t->tx;
  $t     = $t->tx(Mojo::Transaction::HTTP->new);

Current transaction, usually a Mojo::Transaction::HTTP object.

  my $ua = $t->ua;
  $t     = $t->ua(Mojo::UserAgent->new);

User agent used for testing.

  my $max_redirects = $t->max_redirects;
  $t                = $t->max_redirects(3);

Maximum number of redirects, defaults to 0.

Test::Mojo inherits all methods from Mojo::Base and implements the following new ones.

  my $url = $t->build_url;

Build absolute Mojo::URL object for test server. Note that this method is EXPERIMENTAL and might change without warning!

  $t->get_ok($t->build_url->userinfo('sri:secr3t')->path('/protected'));

  $t = $t->content_is('working!');
  $t = $t->content_is('working!', 'right content');

Check response content for exact match.

  $t = $t->content_isnt('working!');
  $t = $t->content_isnt('working!', 'different content');

Opposite of content_is.

  $t = $t->content_like(qr/working!/);
  $t = $t->content_like(qr/working!/, 'right content');

Check response content for similar match.

  $t = $t->content_unlike(qr/working!/);
  $t = $t->content_unlike(qr/working!/, 'different content');

Opposite of content_like.

  $t = $t->content_type_is('text/html');

Check response Content-Type header for exact match.

  $t = $t->content_type_isnt('text/html');

Opposite of content_type_is.

  $t = $t->content_type_like(qr/text/);
  $t = $t->content_type_like(qr/text/, 'right content type');

Check response Content-Type header for similar match.

  $t = $t->content_type_unlike(qr/text/);
  $t = $t->content_type_unlike(qr/text/, 'different content type');

Opposite of content_type_like.

  $t = $t->delete_ok('/foo');
  $t = $t->delete_ok('/foo', {Accept => '*/*'});
  $t = $t->delete_ok('/foo', 'Hi!');
  $t = $t->delete_ok('/foo', {Accept => '*/*'}, 'Hi!');

Perform a DELETE request and check for success.

  $t = $t->element_exists('div.foo[x=y]');
  $t = $t->element_exists('html head title', 'has a title');

Checks for existence of the CSS3 selectors first matching XML/HTML element with Mojo::DOM.

  $t = $t->element_exists_not('div.foo[x=y]');
  $t = $t->element_exists_not('html head title', 'has no title');

Opposite of element_exists.

  $t = $t->get_ok('/foo');
  $t = $t->get_ok('/foo', {Accept => '*/*'});
  $t = $t->get_ok('/foo', 'Hi!');
  $t = $t->get_ok('/foo', {Accept => '*/*'}, 'Hi!');

Perform a GET request and check for success.

  $t = $t->head_ok('/foo');
  $t = $t->head_ok('/foo', {Accept => '*/*'});
  $t = $t->head_ok('/foo', 'Hi!');
  $t = $t->head_ok('/foo', {Accept => '*/*'}, 'Hi!');

Perform a HEAD request and check for success.

  $t = $t->header_is(Expect => 'fun');

Check response header for exact match.

  $t = $t->header_isnt(Expect => 'fun');

Opposite of header_is.

  $t = $t->header_like(Expect => qr/fun/);
  $t = $t->header_like(Expect => qr/fun/, 'right header');

Check response header for similar match.

  $t = $t->header_like(Expect => qr/fun/);
  $t = $t->header_like(Expect => qr/fun/, 'different header');

Opposite of header_like.

  $t = $t->json_content_is([1, 2, 3]);
  $t = $t->json_content_is([1, 2, 3], 'right content!');
  $t = $t->json_content_is({foo => 'bar', baz => 23}, 'right content!');

Check response content for JSON data.

  $t = $t->post_ok('/foo');
  $t = $t->post_ok('/foo', {Accept => '*/*'});
  $t = $t->post_ok('/foo', 'Hi!');
  $t = $t->post_ok('/foo', {Accept => '*/*'}, 'Hi!');
  $t = $t->post_ok('/foo', 'Hi!', 'request worked');

Perform a POST request and check for success.

  $t = $t->post_form_ok('/foo' => {test => 123});
  $t = $t->post_form_ok('/foo' => 'UTF-8' => {test => 123});
  $t = $t->post_form_ok('/foo', {test => 123}, {Accept => '*/*'});
  $t = $t->post_form_ok('/foo', 'UTF-8', {test => 123}, {Accept => '*/*'});
  $t = $t->post_form_ok('/foo', {test => 123}, 'Hi!');
  $t = $t->post_form_ok('/foo', 'UTF-8', {test => 123}, 'Hi!');
  $t = $t->post_form_ok('/foo', {test => 123}, {Accept => '*/*'}, 'Hi!');
  $t = $t->post_form_ok(
    '/foo',
    'UTF-8',
    {test   => 123},
    {Accept => '*/*'},
    'Hi!'
  );

Submit a POST form and check for success.

  $t = $t->put_ok('/foo');
  $t = $t->put_ok('/foo', {Accept => '*/*'});
  $t = $t->put_ok('/foo', 'Hi!');
  $t = $t->put_ok('/foo', {Accept => '*/*'}, 'Hi!');

Perform a PUT request and check for success.

  $t = $t->reset_session;

Reset user agent session.

  $t = $t->status_is(200);

Check response status for exact match.

  $t = $t->status_isnt(200);

Opposite of status_is.

  $t = $t->text_is('div.foo[x=y]' => 'Hello!');
  $t = $t->text_is('html head title' => 'Hello!', 'right title');

Checks text content of the CSS3 selectors first matching XML/HTML element for exact match with Mojo::DOM.

  $t = $t->text_isnt('div.foo[x=y]' => 'Hello!');
  $t = $t->text_isnt('html head title' => 'Hello!', 'different title');

Opposite of text_is.

  $t = $t->text_like('div.foo[x=y]' => qr/Hello/);
  $t = $t->text_like('html head title' => qr/Hello/, 'right title');

Checks text content of the CSS3 selectors first matching XML/HTML element for similar match with Mojo::DOM.

  $t = $t->text_unlike('div.foo[x=y]' => qr/Hello/);
  $t = $t->text_unlike('html head title' => qr/Hello/, 'different title');

Opposite of text_like.

Mojolicious, Mojolicious::Guides, http://mojolicio.us.