Moose::Meta::TypeCoercion::Union - The Moose Type Coercion metaclass for Unions

Moose documentation Contained in the Moose distribution.

Index

Code Index:

NAME

Top

Moose::Meta::TypeCoercion::Union - The Moose Type Coercion metaclass for Unions

VERSION

Top

version 2.0010

DESCRIPTION

Top

This is a subclass of Moose::Meta::TypeCoercion that is used for Moose::Meta::TypeConstraint::Union objects. =head1 METHODS

$coercion->has_coercion_for_type

This method always returns false.

$coercion->add_type_coercions

This method always throws an error. You cannot add coercions to a union type coercion.

$coercion->coerce($value)

This method will coerce by trying the coercions for each type in the union.

BUGS

Top

See BUGS in Moose for details on reporting bugs.

AUTHOR

Top

Stevan Little <stevan@iinteractive.com>

COPYRIGHT AND LICENSE

Top

This software is copyright (c) 2011 by Infinity Interactive, Inc..

This is free software; you can redistribute it and/or modify it under the same terms as the Perl 5 programming language system itself.

Moose documentation Contained in the Moose distribution. 
package Moose::Meta::TypeCoercion::Union;
BEGIN {
  $Moose::Meta::TypeCoercion::Union::AUTHORITY = 'cpan:STEVAN';
}
BEGIN {
  $Moose::Meta::TypeCoercion::Union::VERSION = '2.0010';
}

use strict;
use warnings;
use metaclass;

use Scalar::Util 'blessed';

use base 'Moose::Meta::TypeCoercion';

sub compile_type_coercion {
    my $self            = shift;
    my $type_constraint = $self->type_constraint;

    (blessed $type_constraint && $type_constraint->isa('Moose::Meta::TypeConstraint::Union'))
     || Moose->throw_error("You can only create a Moose::Meta::TypeCoercion::Union for a " .
                "Moose::Meta::TypeConstraint::Union, not a $type_constraint");

    $self->_compiled_type_coercion(
        sub {
            my $value = shift;

            foreach my $type ( grep { $_->has_coercion }
                @{ $type_constraint->type_constraints } ) {
                my $temp = $type->coerce($value);
                return $temp if $type_constraint->check($temp);
            }

            return $value;
        }
    );
}

sub has_coercion_for_type { 0 }

sub add_type_coercions {
    require Moose;
    Moose->throw_error("Cannot add additional type coercions to Union types");
}

1;

# ABSTRACT: The Moose Type Coercion metaclass for Unions





__END__