Test::Moose - Test functions for Moose specific features

Moose documentation

Contained in the Moose distribution.

Index

NAME
VERSION
SYNOPSIS
DESCRIPTION
EXPORTED FUNCTIONS
TODO
SEE ALSO
- Test::More
BUGS
AUTHOR
COPYRIGHT AND LICENSE

Code Index:

package Test::Moose
__END__
EOF

NAME

Test::Moose - Test functions for Moose specific features

VERSION

version 2.0010

SYNOPSIS

  use Test::More plan => 1;
  use Test::Moose;

  meta_ok($class_or_obj, "... Foo has a ->meta");
  does_ok($class_or_obj, $role, "... Foo does the Baz role");
  has_attribute_ok($class_or_obj, $attr_name, "... Foo has the 'bar' attribute");

DESCRIPTION

This module provides some useful test functions for Moose based classes. It is an experimental first release, so comments and suggestions are very welcome.

EXPORTED FUNCTIONS

meta_ok ($class_or_object): Tests if a class or object has a metaclass.
does_ok ($class_or_object, $role, ?$message): Tests if a class or object does a certain role, similar to what isa_ok does for the isa method.
has_attribute_ok($class_or_object, $attr_name, ?$message): Tests if a class or object has a certain attribute, similar to what can_ok does for the methods.
with_immutable { CODE } @class_names: Runs CODE (which should contain normal tests) twice, and make each class in @class_names immutable in between the two runs.

TODO

Convert the Moose test suite to use this module.
Here is a list of possible functions to write

SEE ALSO

Test::More

BUGS

See BUGS in Moose for details on reporting bugs.

AUTHOR

Stevan Little <stevan@iinteractive.com>

COPYRIGHT AND LICENSE

This software is copyright (c) 2011 by Infinity Interactive, Inc..

This is free software; you can redistribute it and/or modify it under the same terms as the Perl 5 programming language system itself.

Moose documentation

Contained in the Moose distribution.

package Test::Moose;
BEGIN {
  $Test::Moose::AUTHORITY = 'cpan:STEVAN';
}
BEGIN {
  $Test::Moose::VERSION = '2.0010';
}

use strict;
use warnings;

use Sub::Exporter;
use Test::Builder;

use List::MoreUtils 'all';
use Moose::Util 'does_role', 'find_meta';

my @exports = qw[
    meta_ok
    does_ok
    has_attribute_ok
    with_immutable
];

Sub::Exporter::setup_exporter({
    exports => \@exports,
    groups  => { default => \@exports }
});

## the test builder instance ...

my $Test = Test::Builder->new;

## exported functions

sub meta_ok ($;$) {
    my ($class_or_obj, $message) = @_;

    $message ||= "The object has a meta";

    if (find_meta($class_or_obj)) {
        return $Test->ok(1, $message)
    }
    else {
        return $Test->ok(0, $message);
    }
}

sub does_ok ($$;$) {
    my ($class_or_obj, $does, $message) = @_;

    $message ||= "The object does $does";

    if (does_role($class_or_obj, $does)) {
        return $Test->ok(1, $message)
    }
    else {
        return $Test->ok(0, $message);
    }
}

sub has_attribute_ok ($$;$) {
    my ($class_or_obj, $attr_name, $message) = @_;

    $message ||= "The object does has an attribute named $attr_name";

    my $meta = find_meta($class_or_obj);

    if ($meta->find_attribute_by_name($attr_name)) {
        return $Test->ok(1, $message)
    }
    else {
        return $Test->ok(0, $message);
    }
}

sub with_immutable (&@) {
    my $block = shift;
    my $before = $Test->current_test;
    $block->();
    Class::MOP::class_of($_)->make_immutable for @_;
    $block->();
    my $num_tests = $Test->current_test - $before;
    return all { $_ } ($Test->summary)[-$num_tests..-1];
}

1;

# ABSTRACT: Test functions for Moose specific features


__END__