MooseX::AttributeHelpers::MethodProvider::ImmutableHash - MooseX::AttributeHelpers::MethodProvider::ImmutableHash documentation

MooseX-AttributeHelpers documentation Contained in the MooseX-AttributeHelpers distribution.

Index

Code Index:

NAME

Top

MooseX::AttributeHelpers::MethodProvider::ImmutableHash

DESCRIPTION

Top

This is a role which provides the method generators for MooseX::AttributeHelpers::Collection::ImmutableHash.

METHODS

Top

meta

PROVIDED METHODS

Top

count

Returns the number of elements in the list.

empty

If the list is populated, returns true. Otherwise, returns false.

exists

Returns true if the given key is present in the hash

defined

Returns true if the value of a given key is defined

get

Returns an element of the hash by its key.

keys

Returns the list of keys in the hash.

values

Returns the list of values in the hash.

kv

Returns the key, value pairs in the hash as array references

elements

Returns the key, value pairs in the hash as a flattened list

BUGS

Top

All complex software has bugs lurking in it, and this module is no exception. If you find a bug please either email me, or add the bug to cpan-RT.

AUTHOR

Top

Stevan Little <stevan@iinteractive.com>

COPYRIGHT AND LICENSE

Top

Copyright 2007-2009 by Infinity Interactive, Inc.

http://www.iinteractive.com

This library is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

MooseX-AttributeHelpers documentation Contained in the MooseX-AttributeHelpers distribution. 
package MooseX::AttributeHelpers::MethodProvider::ImmutableHash;
use Moose::Role;

our $VERSION   = '0.23';
$VERSION = eval $VERSION;
our $AUTHORITY = 'cpan:STEVAN';

sub exists : method {
    my ($attr, $reader, $writer) = @_;
    return sub { CORE::exists $reader->($_[0])->{$_[1]} ? 1 : 0 };
}

sub defined : method {
    my ($attr, $reader, $writer) = @_;
    return sub { CORE::defined $reader->($_[0])->{$_[1]} ? 1 : 0 };
}

sub get : method {
    my ($attr, $reader, $writer) = @_;
    return sub {
        if ( @_ == 2 ) {
            $reader->($_[0])->{$_[1]}
        } else {
            my ( $self, @keys ) = @_;
            @{ $reader->($self) }{@keys}
        }
    };
}

sub keys : method {
    my ($attr, $reader, $writer) = @_;
    return sub { CORE::keys %{$reader->($_[0])} };
}

sub values : method {
    my ($attr, $reader, $writer) = @_;
    return sub { CORE::values %{$reader->($_[0])} };
}

sub kv : method {
    my ($attr, $reader, $writer) = @_;
    return sub {
        my $h = $reader->($_[0]);
        map {
            [ $_, $h->{$_} ]
        } CORE::keys %{$h}
    };
}

sub elements : method {
    my ($attr, $reader, $writer) = @_;
    return sub {
        my $h = $reader->($_[0]);
        map {
            $_, $h->{$_}
        } CORE::keys %{$h}
    };
}

sub count : method {
    my ($attr, $reader, $writer) = @_;
    return sub { scalar CORE::keys %{$reader->($_[0])} };
}

sub empty : method {
    my ($attr, $reader, $writer) = @_;
    return sub { scalar CORE::keys %{$reader->($_[0])} ? 1 : 0 };
}

1;

__END__