MooseX::AttributeHelpers::Trait::Counter - MooseX::AttributeHelpers::Trait::Counter documentation

MooseX-AttributeHelpers documentation Contained in the MooseX-AttributeHelpers distribution.

Index

Code Index:

NAME

Top

MooseX::AttributeHelpers::Counter

SYNOPSIS

Top

  package MyHomePage;
  use Moose;
  use MooseX::AttributeHelpers;

  has 'counter' => (
      metaclass => 'Counter',
      is        => 'ro',
      isa       => 'Num',
      default   => sub { 0 },
      provides  => {
          inc => 'inc_counter',
          dec => 'dec_counter',          
          reset => 'reset_counter',
      }
  );

  my $page = MyHomePage->new();
  $page->inc_counter; # same as $page->counter($page->counter + 1);
  $page->dec_counter; # same as $page->counter($page->counter - 1);

DESCRIPTION

Top

This module provides a simple counter attribute, which can be incremented and decremeneted.

If your attribute definition does not include any of is, isa, default or provides but does use the Counter metaclass, then this module applies defaults as in the SYNOPSIS above. This allows for a very basic counter definition:

  has 'foo' => (metaclass => 'Counter');
  $obj->inc_foo;

METHODS

Top

meta
method_provider
has_method_provider
helper_type
process_options_for_provides

Run before its superclass method.

check_provides_values

Run after its superclass method.

PROVIDED METHODS

Top

It is important to note that all those methods do in place modification of the value stored in the attribute.

set

Set the counter to the specified value.

inc

Increments the value stored in this slot by 1. Providing an argument will cause the counter to be increased by specified amount.

dec

Decrements the value stored in this slot by 1. Providing an argument will cause the counter to be increased by specified amount.

reset

Resets the value stored in this slot to it's default value.

BUGS

Top

All complex software has bugs lurking in it, and this module is no exception. If you find a bug please either email me, or add the bug to cpan-RT.

AUTHOR

Top

Stevan Little <stevan@iinteractive.com>

COPYRIGHT AND LICENSE

Top

Copyright 2007-2009 by Infinity Interactive, Inc.

http://www.iinteractive.com

This library is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

MooseX-AttributeHelpers documentation Contained in the MooseX-AttributeHelpers distribution. 
package MooseX::AttributeHelpers::Trait::Counter;
use Moose::Role;

our $VERSION   = '0.23';
$VERSION = eval $VERSION;
our $AUTHORITY = 'cpan:STEVAN';

use MooseX::AttributeHelpers::MethodProvider::Counter;

with 'MooseX::AttributeHelpers::Trait::Base';

has 'method_provider' => (
    is        => 'ro',
    isa       => 'ClassName',
    predicate => 'has_method_provider',
    default   => 'MooseX::AttributeHelpers::MethodProvider::Counter',
);

sub helper_type { 'Num' }

before 'process_options_for_provides' => sub {
    my ($self, $options, $name) = @_;

    # Set some default attribute options here unless already defined
    if ((my $type = $self->helper_type) && !exists $options->{isa}){
        $options->{isa} = $type;
    }

    $options->{is}      = 'ro' unless exists $options->{is};
    $options->{default} = 0    unless exists $options->{default};
};

after 'check_provides_values' => sub {
    my $self     = shift;
    my $provides = $self->provides;

    unless (scalar keys %$provides) {
        my $method_constructors = $self->method_constructors;
        my $attr_name           = $self->name;

        foreach my $method (keys %$method_constructors) {
            $provides->{$method} = ($method . '_' . $attr_name);
        }
    }
};

no Moose::Role;

1;

__END__