MooseX::Storage::Basic - The simplest level of serialization

MooseX-Storage documentation Contained in the MooseX-Storage distribution.

Index

Code Index:

NAME

Top

MooseX::Storage::Basic - The simplest level of serialization

SYNOPSIS

Top

  package Point;
  use Moose;
  use MooseX::Storage;

  our $VERSION = '0.01';

  with Storage;

  has 'x' => (is => 'rw', isa => 'Int');
  has 'y' => (is => 'rw', isa => 'Int');

  1;

  my $p = Point->new(x => 10, y => 10);

  ## methods to pack/unpack an
  ## object in perl data structures

  # pack the class into a hash
  $p->pack(); # { __CLASS__ => 'Point-0.01', x => 10, y => 10 }

  # unpack the hash into a class
  my $p2 = Point->unpack({ __CLASS__ => 'Point-0.01', x => 10, y => 10 });

  # unpack the hash, with insertion of paramaters
  my $p3 = Point->unpack( $p->pack, inject => { x => 11 } );

DESCRIPTION

Top

This is the most basic form of serialization. This is used by default but the exported Storage function.

METHODS

Top

pack ([ disable_cycle_check = 1])>

Providing the disable_cycle_check argument disables checks for any cyclical references. The current implementation for this check is rather naive, so if you know what you are doing, you can bypass this check.

This trait is applied on a perl-case basis. To set this flag for all objects that inherit from this role, see MooseX::Storage::Traits::DisableCycleDetection.

unpack ($data [, insert = { key => val, ... } ] )>

Providing the insert argument let's you supply additional arguments to the class' new function, or override ones from the serialized data.

Introspection

meta

BUGS

Top

All complex software has bugs lurking in it, and this module is no exception. If you find a bug please either email me, or add the bug to cpan-RT.

AUTHOR

Top

Chris Prather <chris.prather@iinteractive.com>

Stevan Little <stevan.little@iinteractive.com>

COPYRIGHT AND LICENSE

Top

Copyright 2007-2008 by Infinity Interactive, Inc.

http://www.iinteractive.com

This library is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

MooseX-Storage documentation Contained in the MooseX-Storage distribution. 
package MooseX::Storage::Basic;
use Moose::Role;

use MooseX::Storage::Engine;
use String::RewritePrefix;

our $VERSION   = '0.30';
our $AUTHORITY = 'cpan:STEVAN';

sub pack {
    my ( $self, %args ) = @_;
    my $e = $self->_storage_get_engine_class(%args)->new( object => $self );
    $e->collapse_object(%args);
}

sub unpack {
    my ($class, $data, %args) = @_;
    my $e = $class->_storage_get_engine_class(%args)->new(class => $class);

    $class->_storage_construct_instance(
        $e->expand_object($data, %args),
        \%args
    );
}

sub _storage_get_engine_class {
    my ($self, %args) = @_;

    return 'MooseX::Storage::Engine'
        unless (
            exists $args{engine_traits}
         && ref($args{engine_traits}) eq 'ARRAY'
         && scalar(@{$args{engine_traits}})
    );

    my @roles = String::RewritePrefix->rewrite(
        {
            '' => 'MooseX::Storage::Engine::Trait::',
            '+' => '',
        },
        @{$args{engine_traits}}
    );

    Moose::Meta::Class->create_anon_class(
        superclasses => ['MooseX::Storage::Engine'],
        roles => [ @roles ],
        cache => 1,
    )->name;
}

sub _storage_construct_instance {
    my ($class, $args, $opts) = @_;
    my %i = defined $opts->{'inject'} ? %{ $opts->{'inject'} } : ();

    $class->new( %$args, %i );
}

no Moose::Role;

1;

__END__