MooseX::Storage::Format::JSON - A JSON serialization role

MooseX-Storage documentation Contained in the MooseX-Storage distribution.

Index

Code Index:

NAME

Top

MooseX::Storage::Format::JSON - A JSON serialization role

SYNOPSIS

Top

  package Point;
  use Moose;
  use MooseX::Storage;

  with Storage('format' => 'JSON');

  has 'x' => (is => 'rw', isa => 'Int');
  has 'y' => (is => 'rw', isa => 'Int');

  1;

  my $p = Point->new(x => 10, y => 10);

  ## methods to freeze/thaw into
  ## a specified serialization format
  ## (in this case JSON)

  # pack the class into a JSON string
  $p->freeze(); # { "__CLASS__" : "Point", "x" : 10, "y" : 10 }

  # unpack the JSON string into a class
  my $p2 = Point->thaw('{ "__CLASS__" : "Point", "x" : 10, "y" : 10 }');

METHODS

Top

freeze
thaw ($json)

Introspection

meta

BUGS

Top

All complex software has bugs lurking in it, and this module is no exception. If you find a bug please either email me, or add the bug to cpan-RT.

AUTHOR

Top

Chris Prather <chris.prather@iinteractive.com>

Stevan Little <stevan.little@iinteractive.com>

Yuval Kogman <yuval.kogman@iinteractive.com>

COPYRIGHT AND LICENSE

Top

Copyright 2007-2008 by Infinity Interactive, Inc.

http://www.iinteractive.com

This library is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

MooseX-Storage documentation Contained in the MooseX-Storage distribution. 
package MooseX::Storage::Format::JSON;
use Moose::Role;

no warnings 'once';

use JSON::Any;
use utf8 ();

our $VERSION   = '0.30';
our $AUTHORITY = 'cpan:STEVAN';

requires 'pack';
requires 'unpack';

sub thaw {
    my ( $class, $json, @args ) = @_;
    utf8::encode($json) if utf8::is_utf8($json);
    $class->unpack( JSON::Any->jsonToObj($json), @args );
}

sub freeze {
    my ( $self, @args ) = @_;
    my $json = JSON::Any->objToJson( $self->pack(@args) );
    utf8::decode($json) if !utf8::is_utf8($json) and utf8::valid($json); # if it's valid utf8 mark it as such
    return $json;
}

no Moose::Role;

1;

__END__