MouseX::AttributeHelpers::Collection::Hash - MouseX::AttributeHelpers::Collection::Hash documentation

    package MyClass;
    use Mouse;
    use MouseX::AttributeHelpers;

    has 'options' => (
        metaclass => 'Collection::Hash',
        is        => 'rw',
        isa       => 'HashRef',
        default   => sub { +{} },
        provides  => {
            set    => 'set_option',
            get    => 'get_option',
            empty  => 'has_options',
            count  => 'num_options',
            delete => 'delete_option',
        },
    );

package MouseX::AttributeHelpers::Collection::Hash;
use Mouse;
use MouseX::AttributeHelpers::Collection::ImmutableHash;

extends 'MouseX::AttributeHelpers::Base';

has '+method_constructors' => (
    default => sub {
        my $attr = MouseX::AttributeHelpers::Collection::ImmutableHash->meta->get_attribute('method_constructors');
        return +{
            %{ $attr->default->() }, # apply MouseX::AttributeHelpers::Collection::ImmutableHash

            set => sub {
                my ($attr, $name) = @_;
                return sub {
                    if (@_ == 3) {
                        $_[0]->$name()->{$_[1]} = $_[2];
                    }
                    else {
                        my $self = shift;
                        my (@k, @v);
                        while (@_) {
                            push @k, shift;
                            push @v, shift;
                        }
                        @{ $self->$name() }{@k} = @v;
                    }
                };
            },
            clear => sub {
                my ($attr, $name) = @_;
                return sub { %{ $_[0]->$name() } = () };
            },
            delete => sub {
                my ($attr, $name) = @_;
                return sub { delete @{ shift->$name() }{@_} };
            },
        };
    },
);

sub helper_type { 'HashRef' }

no Mouse;
__PACKAGE__->meta->make_immutable(inline_constructor => 0);
__END__