MozRepl::Log - MozRepl logging class

    use MozRepl;

    my $repl = MozRepl->new;
    $repl->setup;

    $repl->log->debug("Look! someone on that wall!");

    my $log = MozRepl::Log->new(qw/info error/);

package MozRepl::Log;

use strict;
use warnings;

use base qw(Class::Accessor::Fast);

__PACKAGE__->mk_accessors(qw/levels/);

our %LEVELS = ();

{
    my @levels = qw/debug info warn error fatal/;

    for ( my $i = 0; $i < @levels; $i++ ) {
        my $name  = $levels[$i];
        my $level += $i;

        $LEVELS{$name} = $level;

        no strict 'refs';

        *{$name} = sub {
            my $self = shift;

            if ( $self->enable($level) ) {
                $self->log( uc($name), @_ );
            }
        };

        *{"is_$name"} = sub {
            my $self = shift;

            return ( $self->enable($level) ) ? 1 : 0;
        };
    }
}

our $VERSION = '0.01';

sub new {
    my ($class, @levels) = @_;
    my $self  = $class->SUPER::new;

    $self->levels(
        [   @levels > 0
            ? grep { exists $LEVELS{$_} } map { lc($_) } @levels
            : keys %LEVELS
        ]
    );

    return $self;
}

sub enable {
    my ( $self, $level ) = @_;
    ( ( grep { $LEVELS{$_} == $level } @{ $self->levels } ) == 1 ) ? 1 : 0;
}

sub log {
    my $self = shift;
    my $level = shift;
    my @messages = map { split(/\n/, $_) } @_;

    my $message = @messages > 1 ? join("\n", "", @messages) : shift @messages;

    warn( sprintf( "[%s] %s\n", $level, $message ) );
}

1;    # End of MozRepl::Log