Net::Amazon::Attribute::ReviewSet - A set of customer reviews

Net-Amazon documentation Contained in the Net-Amazon distribution.

Index

Code Index:

NAME

Top

Net::Amazon::Attribute::ReviewSet - A set of customer reviews

SYNOPSIS

Top

    use Net::Amazon::Attribute::ReviewSet;
    my $rev = Net::Amazon::Attribute::Review->new(
        average_customer_rating => $avg,
        total_reviews  => $total,
        );

DESCRIPTION

Top

Net::Amazon::Attribute::ReviewSet holds a list of customer reviews, each of type Net::Amazon::Attribute::Review.

METHODS

$self->reviews()

Returns a list of Net::Amazon::Attribute::Review objects.

$self->average_customer_rating()

Accessor for the average customer rating, a numeric value.

$self->total_reviews()

Accessor for the total number of reviews. Please note that this might not be equal to the number of reviews held in the list, since there might be less customer reviews than total reviews (reviews can also be non-customer-reviews, but they're not available by the web service as of Aug 2003).

$self->total_review_pages

Accessor for the total number of review pages.

$self->add_review($rev)

Add a Net::Amazon::Attribute::Review object to the list. (Used internally only).

AUTHOR

Top

Mike Schilli, <m@perlmeister.com>

COPYRIGHT AND LICENSE

Top

Copyright 2003 by Mike Schilli <m@perlmeister.com>

This library is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

Net-Amazon documentation Contained in the Net-Amazon distribution. 
######################################################################
package Net::Amazon::Attribute::ReviewSet;
######################################################################
use warnings;
use strict;
use Log::Log4perl qw(:easy);
use Net::Amazon::Attribute::Review;
use base qw(Net::Amazon);

__PACKAGE__->make_accessor($_) for qw(average_customer_rating total_reviews 
                                      total_review_pages);

##################################################
sub new {
##################################################
    my($class, %options) = @_;

    my $self = {
        reviews => [],  # list of reviews
    };

    bless $self, $class;
}

###########################################
sub add_review {
###########################################
    my($self, $review) = @_;

    if(ref $review ne "Net::Amazon::Attribute::Review") {
        warn "add_review called with type ", ref $review;
        return undef;
    }

    push @{$self->{reviews}}, $review;
}

###########################################
sub reviews {
###########################################
    my($self) = @_;

    return @{$self->{reviews}};
}

##################################################
sub init_via_xmlref {
##################################################
    my($self, $xmlref) = @_;

    my @pairs = qw(AverageRating    average_customer_rating
                   TotalReviews     total_reviews
                   TotalReviewPages total_review_pages);

    while(my($field, $method) = splice @pairs, 0, 2) {
        
        if(exists $xmlref->{$field}) {
            DEBUG "Setting $field via $method to $xmlref->{$field}";
            $self->$method($xmlref->{$field});
        } 
    }

    for my $review_xmlref (@{$xmlref->{Review}}) {
        my $review = Net::Amazon::Attribute::Review->new();
        $review->init_via_xmlref($review_xmlref);
        DEBUG "Adding review ", $review->summary();
        $self->add_review($review);
    }
}

1;

__END__