Net::DBus::RemoteService - Access services provided on the bus

Net-DBus documentation Contained in the Net-DBus distribution.

Index

Code Index:

NAME

Top

Net::DBus::RemoteService - Access services provided on the bus

SYNOPSIS

Top

  my $bus = Net::DBus->find;
  my $service = $bus->get_service("org.freedesktop.DBus");

  my $object = $service->get_object("/org/freedesktop/DBus");
  foreach (@{$object->ListNames}) {
    print "$_\n";
  }

DESCRIPTION

Top

This object provides a handle to a remote service on the bus. From this handle it is possible to access objects associated with the service. If a service is not running, an attempt will be made to activate it the first time a method is called against one of its objects.

METHODS

Top

my $service = Net::DBus::RemoteService->new($bus, $owner, $service_name);

Creates a new handle for a remote service. The $bus parameter is an instance of Net::DBus, $owner is the name of the client providing the service, while $service_name is the well known name of the service on the bus. Service names consist of two or more tokens, separated by periods, while the tokens comprise the letters a-z, A-Z, 0-9 and _, for example org.freedesktop.DBus. There is generally no need to call this constructor, instead the get_service method on Net::DBus should be used. This caches handles to remote services, eliminating repeated retrieval of introspection data.

my $bus = $service->get_bus;

Retrieves a handle for the bus to which this service is attached. The returned object will be an instance of Net::DBus.

my $service_name = $service->get_service_name

Retrieves the name of the remote service as known to the bus.

my $owner_name = $service->get_owner_name;

Retrieves the name of the client owning the service at the time it was connected to.

my $object = $service->get_object($object_path[, $interface]);

Retrieves a handle to the remote object provided by the service with the name of $object_path. If the optional $interface parameter is provided, the object will immediately be cast to the designated interface. NB, it is only neccessary to cast an object to a specific interface if there are multiple interfaces on the object providing methods with the same name, or the remote object does support introspection. The returned object will be an instance of Net::DBus::RemoteObject.

AUTHOR

Top

Daniel Berrange <dan@berrange.com>

COPYRIGHT

Top

Copright (C) 2004-2005, Daniel Berrange.

SEE ALSO

Top

Net::DBus::RemoteObject, Net::DBus::Service, Net::DBus

Net-DBus documentation Contained in the Net-DBus distribution. 
# -*- perl -*-
#
# Copyright (C) 2004-2006 Daniel P. Berrange
#
# This program is free software; You can redistribute it and/or modify
# it under the same terms as Perl itself. Either:
#
# a) the GNU General Public License as published by the Free
#   Software Foundation; either version 2, or (at your option) any
#   later version,
#
# or
#
# b) the "Artistic License"
#
# The file "COPYING" distributed along with this file provides full
# details of the terms and conditions of the two licenses.


package Net::DBus::RemoteService;

use 5.006;
use strict;
use warnings;

use Net::DBus::RemoteObject;


sub new {
    my $class = shift;
    my $self = {};

    $self->{bus} = shift;
    $self->{owner_name} = shift;
    $self->{service_name} = shift;
    $self->{objects} = {};

    bless $self, $class;

    return $self;
}



sub get_bus {
    my $self = shift;

    return $self->{bus};
}



sub get_service_name {
    my $self = shift;
    return $self->{service_name};
}


sub get_owner_name {
    my $self = shift;
    return $self->{owner_name};
}


sub get_object {
    my $self = shift;
    my $object_path = shift;
    
    unless (defined $self->{objects}->{$object_path}) {
	$self->{objects}->{$object_path} = Net::DBus::RemoteObject->new($self,
									$object_path);
    }

    if (@_) {
	my $interface = shift;
	return $self->{objects}->{$object_path}->as_interface($interface);
    } else {
	return $self->{objects}->{$object_path};
    }
}

1;