Net::DNS::RR::AFSDB - DNS AFSDB resource record

    print "subtype = ", $rr->subtype, "\n";

    print "hostname = ", $rr->hostname, "\n";

package Net::DNS::RR::AFSDB;
#
# $Id: AFSDB.pm 718 2008-02-26 21:49:20Z olaf $
#
use strict;

BEGIN { 
    eval { require bytes; }
} 

use vars qw(@ISA $VERSION);

@ISA     = qw(Net::DNS::RR);
$VERSION = (qw$LastChangedRevision: 718 $)[1];

sub new {
	my ($class, $self, $data, $offset) = @_;

	if ($self->{"rdlength"} > 0) {
		my ($subtype) = unpack("\@$offset n", $$data);
		$offset += Net::DNS::INT16SZ();
		my($hostname) = Net::DNS::Packet::dn_expand($data, $offset);
		$self->{"subtype"} = $subtype;
		$self->{"hostname"} = $hostname;
	}

	return bless $self, $class;
}

sub new_from_string {
	my ($class, $self, $string) = @_;

	if ($string && ($string =~ /^(\d+)\s+(\S+)$/)) {
		$self->{"subtype"}  = $1;
		$self->{"hostname"} = Net::DNS::stripdot($2);

	}

	return bless $self, $class;
}

sub rdatastr {
	my $self = shift;

	return exists $self->{"subtype"}
	       ? "$self->{subtype} $self->{hostname}."
	       : '';
}

sub rr_rdata {
	my ($self, $packet, $offset) = @_;
	my $rdata = "";

	if (exists $self->{"subtype"}) {
		$rdata .= pack("n", $self->{"subtype"});
		$rdata .= $packet->dn_comp($self->{"hostname"},
					   $offset + length $rdata);
	}

	return $rdata;
}


sub _normalize_dnames {
	my $self=shift;
	$self->_normalize_ownername();

	foreach my $attribute ( qw ( hostname ) ){
		$self->{$attribute}=Net::DNS::stripdot($self->{$attribute}) if defined $self->{$attribute};
	}

}




sub _canonicalRdata {
    # rdata contains a compressed domainname... we should not have that.
	my ($self) = @_;
	my $rdata;
	if (exists $self->{"subtype"}) {
	    $rdata .= pack("n", $self->{"subtype"});
	    $rdata .=  $self->_name2wire(lc($self->{"hostname"}));
	}
	return $rdata;
}


1;
__END__