Net::DNS::RR::HINFO - DNS HINFO resource record

    print "cpu = ", $rr->cpu, "\n";

    print "os = ", $rr->os, "\n";

package Net::DNS::RR::HINFO;
#
# $Id: HINFO.pm 833 2009-12-28 16:25:09Z olaf $
#
use strict;
BEGIN { 
    eval { require bytes; }
} 
use vars qw(@ISA $VERSION);
use Net::DNS::RR::TXT;

@ISA     = qw(Net::DNS::RR Net::DNS::RR::TXT);
$VERSION = (qw$LastChangedRevision: 833 $)[1];

sub new {
	my ($class, $self, $data, $offset) = @_;

	if ($self->{"rdlength"} > 0) {
		my ($cpu, $os, $len);

		($len) = unpack("\@$offset C", $$data);
		++$offset;
		$cpu = substr($$data, $offset, $len);
		$offset += $len;

		($len) = unpack("\@$offset C", $$data);
		++$offset;
		$os = substr($$data, $offset, $len);
		$offset += $len;

		$self->{"cpu"} = $cpu;
		$self->{"os"}  = $os;
	}

	return bless $self, $class;
}

sub new_from_string {
	my ( $class, $self, $rdata_string ) = @_ ;
	
	bless $self, $class;
        return $self unless $rdata_string;
	$self->_build_char_str_list($rdata_string);
	my @elements= $self->char_str_list();
	if (@elements==2){
		
		
		$self->{"cpu"} = $elements[0];
		$self->{"os"}  = $elements[1];
	}else{
		return;
	}
	
	
	return $self;
}

sub rdatastr {
	my $self = shift;
	
	return $self->{"cpu"}
	  ? qq("$self->{cpu}" "$self->{os}")
	    : '';
}

sub rr_rdata {
	my $self = shift;
	my $rdata = "";

	if (exists $self->{"cpu"}) {
		$rdata .= pack("C", length $self->{"cpu"});
		$rdata .= $self->{"cpu"};

		$rdata .= pack("C", length $self->{"os"});
		$rdata .= $self->{"os"};
	}

	return $rdata;
}

1;
__END__