Net::DNS::RR::SRV - DNS SRV resource record

Net-DNS documentation Contained in the Net-DNS distribution.

Index

Code Index:

NAME

Top

Net::DNS::RR::SRV - DNS SRV resource record

SYNOPSIS

Top

use Net::DNS::RR;

DESCRIPTION

Top

Class for DNS Service (SRV) resource records.

METHODS

Top

priority

    print "priority = ", $rr->priority, "\n";

Returns the priority for this target host.

weight

    print "weight = ", $rr->weight, "\n";

Returns the weight for this target host.

port

    print "port = ", $rr->port, "\n";

Returns the port on this target host for the service.

target

    print "target = ", $rr->target, "\n";

Returns the target host.

COPYRIGHT

Top

Copyright (c) 1997-2002 Michael Fuhr.

Portions Copyright (c) 2002-2004 Chris Reinhardt.

All rights reserved. This program is free software; you may redistribute it and/or modify it under the same terms as Perl itself.

SEE ALSO

Top

perl(1), Net::DNS, Net::DNS::Resolver, Net::DNS::Packet, Net::DNS::Header, Net::DNS::Question, Net::DNS::RR, RFC 2782

Net-DNS documentation Contained in the Net-DNS distribution. 
package Net::DNS::RR::SRV;
#
# $Id: SRV.pm 718 2008-02-26 21:49:20Z olaf $
#
use strict;
BEGIN { 
    eval { require bytes; }
} 
use vars qw(@ISA $VERSION);

@ISA     = qw(Net::DNS::RR);
$VERSION = (qw$LastChangedRevision: 718 $)[1];



__PACKAGE__->set_rrsort_func("priority",
			       sub {
				   my ($a,$b)=($Net::DNS::a,$Net::DNS::b);
				   $a->{'priority'} <=> $b->{'priority'}
				   ||
				       $b->{'weight'} <=> $a->{'weight'}
}
);


__PACKAGE__->set_rrsort_func("default_sort",
			       __PACKAGE__->get_rrsort_func("priority")

    );

__PACKAGE__->set_rrsort_func("weight",
			       sub {
				   my ($a,$b)=($Net::DNS::a,$Net::DNS::b);
				   $b->{"weight"} <=> $a->{"weight"}
				   ||
				       $a->{"priority"} <=> $b->{"priority"}
}
);



sub new {
	my ($class, $self, $data, $offset) = @_;

	if ($self->{'rdlength'} > 0) {
		@{$self}{qw(priority weight port)} = unpack("\@$offset n3", $$data);
		$offset += 3 * Net::DNS::INT16SZ();
		
		($self->{'target'}) = Net::DNS::Packet::dn_expand($data, $offset);
	}

	return bless $self, $class;
}

sub new_from_string {
	my ($class, $self, $string) = @_;

	if ($string && ($string =~ /^(\d+)\s+(\d+)\s+(\d+)\s+(\S+)$/)) {
		@{$self}{qw(priority weight port target)} = ($1, $2, $3, $4);

		$self->{'target'} =~ s/\.+$//;
	}

	return bless $self, $class;
}

sub rdatastr {
	my $self = shift;
	my $rdatastr;

	if (exists $self->{'priority'}) {
		$rdatastr = join(' ', @{$self}{qw(priority weight port target)});
		$rdatastr =~ s/(.*[^\.])$/$1./;
	} else {
		$rdatastr = '';
	}

	return $rdatastr;
}

sub rr_rdata {
	my ($self, $packet, $offset) = @_;
	my $rdata = '';

	if (exists $self->{'priority'}) {
		$rdata .= pack('n3', @{$self}{qw(priority weight port)});
		$rdata .=  $self->_name2wire ($self->{"target"});

	      }
	
	return $rdata;
}

sub _normalize_dnames {
	my $self=shift;
	$self->_normalize_ownername();
	$self->{'target'}=Net::DNS::stripdot($self->{'target'}) if defined $self->{'target'};
}





1;
__END__