Net::DRI::Protocol::EPP::Extensions::AT::Result - ENUM.AT Result Condition EPP Mapping for Net::DRI

## Domain Registry Interface, ENUM.AT Result Condition
## Contributed by Michael Braunoeder from ENUM.AT <michael.braunoeder@enum.at>
##
## Copyright (c) 2006,2007 Patrick Mevzek <netdri@dotandco.com>. All rights reserved.
##
## This file is part of Net::DRI
##
## Net::DRI is free software; you can redistribute it and/or modify
## it under the terms of the GNU General Public License as published by
## the Free Software Foundation; either version 2 of the License, or
## (at your option) any later version.
##
## See the LICENSE file that comes with this distribution for more details.
#
# 
#
####################################################################################################

package Net::DRI::Protocol::EPP::Extensions::AT::Result;

use strict;

use Net::DRI::Util;
use Net::DRI::Exception;

our $VERSION=do { my @r=(q$Revision: 1.4 $=~/\d+/g); sprintf("%d".".%02d" x $#r, @r); };
our $NS='http://www.enum.at/rxsd/ienum43-result-1.0';

####################################################################################################

sub register_commands
{
 my ($class,$version)=@_;
 my %tmp=(
           login => [ undef, \&condition_parse ],
           check  => [ undef, \&condition_parse ],
           info   => [ undef, \&condition_parse ],
           transfer_query  => [ undef, \&condition_parse ],
           create => [ undef, \&condition_parse ],
           delete => [ undef, \&condition_parse],
           transfer_request => [ undef, \&condition_parse ],
           transfer_cancel  => [ undef,\&condition_parse ],
           transfer_answer  => [ undef,\&condition_parse ],
           update => [ undef, \&condition_parse ],
         );

 return { 'domain' => \%tmp };
}


sub condition_parse
{
 my ($po,$otype,$oaction,$oname,$rinfo)=@_;
 my $mes=$po->message();

 my $condata=$mes->get_extension($NS,'conditions');
 return unless $condata;

 my @conditions;

 foreach my $el ($condata->getElementsByTagNameNS($NS,'condition'))
 {
  my %con;
  my $c=$el->getFirstChild();

  $con{code}=$el->getAttribute('code') if $el->getAttribute('code');
  $con{severity}=$el->getAttribute('severity') if $el->getAttribute('severity');

  while ($c)
  {
   next unless ($c->nodeType() == 1); ## only for element nodes
   my $name=$c->localname() || $c->nodeName();
   next unless $name;
   if ($name=~m/^(msg|details)$/)
   {
    $con{$1}=$c->getFirstChild()->getData();
   }
  } continue { $c=$c->getNextSibling(); }
  push @conditions,\%con;
 }

 $rinfo->{domain}->{$oname}->{conditions}=\@conditions;
}

####################################################################################################
1;