Net::Frame::Layer::LLTD::QueryResp - LLTD QueryResp upper layer object

   use Net::Frame::Layer::LLTD::QueryResp;

   # Build a layer
   my $layer = Net::Frame::Layer::LLTD::QueryResp->new(
      flags          => 0,
      numDescs       => 0,
      recveeDescList => [],
   );
   $layer->pack;

   print 'RAW: '.$layer->dump."\n";

   # Read a raw layer
   my $layer = Net::Frame::Layer::LLTD::QueryResp->new(raw => $raw);
   $layer->unpack;

   print $layer->print."\n";
   print 'PAYLOAD: '.unpack('H*', $layer->payload)."\n"
      if $layer->payload;

#
# $Id: QueryResp.pm,v 1.2 2007/03/15 18:23:52 gomor Exp $
#
package Net::Frame::Layer::LLTD::QueryResp;
use strict;
use warnings;

use Net::Frame::Layer qw(:consts :subs);
require Exporter;
our @ISA = qw(Net::Frame::Layer Exporter);

our @AS = qw(
   flags
   numDescs
);
our @AA = qw(
   recveeDescList
);
__PACKAGE__->cgBuildIndices;
__PACKAGE__->cgBuildAccessorsScalar(\@AS);
__PACKAGE__->cgBuildAccessorsArray (\@AA);

use Net::Frame::Layer::LLTD::RecveeDesc;

sub new {
   shift->SUPER::new(
      flags          => 0,
      numDescs       => 0,
      recveeDescList => [],
      @_,
   );
}

sub getRecveeDescListLength {
   my $self = shift;
   my $len = 0;
   for ($self->recveeDescList) {
      $len += $_->getLength;
   }
   $len;
}

sub getLength {
   my $self = shift;
   my $len = 2;
   $len += $self->getRecveeDescListLength if $self->recveeDescList;
   $len;
}

sub pack {
   my $self = shift;

   my $raw = $self->SUPER::pack('CC', $self->flags, $self->numDescs)
      or return undef;

   for ($self->recveeDescList) {
      $raw .= $_->pack;
   }

   $self->raw($raw);
}

sub unpack {
   my $self = shift;

   my ($flags, $numDescs, $payload) =
      $self->SUPER::unpack('CC a*', $self->raw)
         or return undef;

   $self->flags($flags);
   $self->numDescs($numDescs);

   my @recveeDescList = ();
   if ($self->numDescs && $self->numDescs > 0) {
      for (1..$self->numDescs) {
         my $recvee = Net::Frame::Layer::LLTD::RecveeDesc->new(raw => $payload);
         $recvee->unpack;
         push @recveeDescList, $recvee;
         $payload = $recvee->payload;
      }
   }

   $self->recveeDescList(\@recveeDescList);
   $self->payload($payload);

   $self;
}

sub encapsulate { shift->nextLayer }

sub print {
   my $self = shift;

   my $l = $self->layer;
   my $buf = sprintf
      "$l: flags:0x%02x  numDescs:%d",
         $self->flags, $self->numDescs;

   for ($self->recveeDescList) {
      $buf .= "\n".$_->print;
   }

   $buf;
}

1;

__END__