Net::NSCA::Client::Library - Types library

  use Net::NSCA::Client::Library qw(Bytes);
  # This will import Bytes type into your namespace as well as some helpers
  # like to_Bytes and is_Bytes. See MooseX::Types for more information.

package Net::NSCA::Client::Library;

use 5.008001;
use strict;
use warnings 'all';

###############################################################################
# METADATA
our $AUTHORITY = 'cpan:DOUGDUDE';
our $VERSION   = '0.009001';

###############################################################################
# MOOSE TYPE DECLARATIONS
use MooseX::Types 0.08 -declare => [qw(
	Bytes
	Hostname
	Timeout
)];

###############################################################################
# MOOSE TYPES
use MooseX::Types::Moose qw(Int Str);
use MooseX::Types::PortNumber qw(PortNumber);

###############################################################################
# MODULES
use Data::Validate::Domain 0.02;

###############################################################################
# ALL IMPORTS BEFORE THIS WILL BE ERASED
use namespace::clean 0.04 -except => [qw(meta)];

###############################################################################
# TYPE DEFINITIONS
subtype Bytes,
	as Str,
	where { !utf8::is_utf8($_) },
	message { 'Cannot have internal utf8 flag on' };

coerce Bytes,
	from Str,
		via { _turn_off_utf8($_) };

subtype Hostname,
	as Str,
	where { Data::Validate::Domain::is_hostname($_) },
	message { 'Must be a valid hostname' };

subtype Timeout,
	as Int,
	where { $_ > 0 },
	message { 'Timeout must be greater than 0' };

# Add external types as types from this package
_add_external_type(
	PortNumber => PortNumber,
);

###############################################################################
# PRIVATE FUNCTIONS
sub _add_external_type {
	my (%pairs) = @_;

	TYPE:
	for my $name (keys %pairs) {
		# Add an entry to the type_storage where the key is simply the name
		# of the type (a simple string) and the value is the string of the
		# type location.
		__PACKAGE__->type_storage->{$name} = "$pairs{$name}";
	}

	return;
}
sub _turn_off_utf8 {
	my ($str) = @_;

	if (utf8::is_utf8($str)) {
		utf8::encode($str);
	}

	return $str;
}

1;

__END__