Net::Packet::CDP::Address - Cisco Discovery Protocol Address format

   use Net::Packet::Consts qw(:cdp);
   require Net::Packet::CDP::Address;

   # Build a layer
   my $layer = Net::Packet::CDP::Address->new(
      protocolType   => NP_CDP_ADDRESS_PROTOCOL_TYPE_NLPID,
      protocolLength => NP_CDP_ADDRESS_PROTOCOL_LENGTH_NLPID,
      protocol       => NP_CDP_ADDRESS_PROTOCOL_IP,
      addressLength  => NP_CDP_ADDRESS_ADDRESS_LENGTH_IP,
      address        => '127.0.0.1',
   );
   $layer->pack;

   print 'RAW: '.unpack('H*', $layer->raw)."\n";

   # Read a raw layer
   my $layer = Net::Packet::CDP::Address->new(raw => $raw);

   print $layer->print."\n";
   print 'PAYLOAD: '.unpack('H*', $layer->payload)."\n"
      if $layer->payload;

#
# $Id: Address.pm 1640 2009-11-09 17:58:27Z gomor $
#
package Net::Packet::CDP::Address;
use strict;
use warnings;

require Net::Packet::Layer4;
our @ISA = qw(Net::Packet::Layer4);

use Net::Packet::Consts qw(:cdp);
use Net::Packet::Utils qw(inetAton inetNtoa);

our @AS = qw(
   protocolType
   protocolLength
   protocol
   addressLength
   address
);
__PACKAGE__->cgBuildIndices;
__PACKAGE__->cgBuildAccessorsScalar(\@AS);

#no strict 'vars';

sub new {
   shift->SUPER::new(
      protocolType   => NP_CDP_ADDRESS_PROTOCOL_TYPE_NLPID,
      protocolLength => NP_CDP_ADDRESS_PROTOCOL_LENGTH_NLPID,
      protocol       => NP_CDP_ADDRESS_PROTOCOL_IP,
      addressLength  => NP_CDP_ADDRESS_ADDRESS_LENGTH_IP,
      address        => '127.0.0.1',
      @_,
   );
}

sub pack {
   my $self = shift;

   $self->raw($self->SUPER::pack('CCCna4',
      $self->protocolType,
      $self->protocolLength,
      $self->protocol,
      $self->addressLength,
      inetAton($self->address),
   )) or return undef;

   1;
}

sub unpack {
   my $self = shift;

   my ($protocolType, $protocolLength, $protocol, $addressLength, $tail) =
      $self->SUPER::unpack('CCCn a*', $self->raw)
         or return undef;

   $self->protocolType($protocolType);
   $self->protocolLength($protocolLength);
   $self->protocol($protocol);
   $self->addressLength($addressLength);

   my $payload;
   if ($protocol eq NP_CDP_ADDRESS_PROTOCOL_IP) {
      my ($address, $lPayload) = $self->SUPER::unpack('a4 a*', $tail)
         or return undef;
      $self->address(inetNtoa($address));
      $payload = $lPayload;
   }
   else {
      # Unknown
   }

   $self->payload($payload);

   1;
}

sub print {
   my $self = shift;

   my $i = $self->is;
   my $l = $self->layer;
   sprintf "$l: $i: protocolType:0x%02x  protocolLength:%d  protocol:0x%02x\n".
           "$l: $i: addressLength:%d  address:%s",
      $self->protocolType, $self->protocolLength, $self->protocol,
      $self->addressLength, $self->address;
}

1;

__END__