Net::Trac::TicketSearch - A ticket search (custom query) in Trac

    my $search = Net::Trac::TicketSearch->new( connection => $trac );

    $search->query(
        owner       => 'hiro',
        status      => { 'not' => [qw(new reopened)] },
        summary     => { 'contains' => 'yatta!' },
        reporter    => [qw( foo@example.com bar@example.com )]
    );

    print $_->id, "\n" for @{$search->results};

use strict;
use warnings;

package Net::Trac::TicketSearch;
use Any::Moose;
use Params::Validate qw(:all);
use URI::Escape qw(uri_escape);

use Net::Trac::Ticket;

has connection => (
    isa => 'Net::Trac::Connection',
    is  => 'ro'
);

has limit   => ( isa => 'Int',      is => 'rw', default => sub { 500 } );
has results => ( isa => 'ArrayRef', is => 'rw', default => sub { [] } );
has url     => ( isa => 'Str',      is => 'rw' );

sub query {
    my $self  = shift;
    my %query = @_;

    my $no_objects = delete $query{'_no_objects'};

    # Clear current results
    $self->results([]);

    # Build a URL from the fields we want and the query
    my $base = '/query?format=tab&order=id&max=' . $self->limit;
    $base .= '&' . join '&', map { "col=$_" } Net::Trac::Ticket->valid_props;

    $self->url( $self->_build_query( $base, \%query ) );

    my $content = $self->connection->_fetch( $self->url )
        or return;

    my $data = $self->connection->_tsv_to_struct( data => \$content);

    unless ( $no_objects ) {
        my @tickets = ();
        for my $ticket_data ( @{$data || []} ) {
            my $ticket = Net::Trac::Ticket->new( connection => $self->connection );
            $ticket->_tweak_ticket_data_for_load($ticket_data);
            my $id = $ticket->load_from_hashref( $ticket_data );
            push @tickets, $ticket if $id;
        }
        return $self->results( \@tickets );
    }
    else {
        return $self->results( $data );
    }
}

our %OPERATORS = (
    undef       => '',
    ''          => '',
    is          => '',
    not         => '!',
    contains    => '~',
    lacks       => '!~',
    startswith  => '^',
    endswith    => '$',
);

sub _build_query {
    my $self  = shift;
    my $base  = shift;
    my $query = shift || {};
    my $defaultop = $OPERATORS{ shift || 'is' } || '';

    for my $key ( keys %$query ) {
        my $value = $query->{$key};

        if ( ref $value eq 'ARRAY' ) {
            $base .= "&$key=" . uri_escape( $defaultop . $_ ) for @$value;
        }
        elsif ( ref $value eq 'HASH' ) {
            my ($op, $v) = %$value;
            $base .= $self->_build_query( '', { $key => $v }, $op );
        }
        elsif ( not ref $value ) {
            $base .= "&$key=" . uri_escape( $defaultop . $value );
        }
        else {
            warn "Skipping '$key = $value' in ticket search: value not understood.";
        }
    }

    return $base;
}

__PACKAGE__->meta->make_immutable;
no Any::Moose;

1;