NetPacket::Ethernet - Assemble and disassemble ethernet packets.

NetPacket documentation Contained in the NetPacket distribution.

Index

Code Index:

NAME

Top

NetPacket::Ethernet - Assemble and disassemble ethernet packets.

VERSION

Top

version 1.1.2

SYNOPSIS

Top

  use NetPacket::Ethernet;

  $eth_obj = NetPacket::Ethernet->decode($raw_pkt);
  $eth_pkt = NetPacket::Ethernet->encode(params...);   # Not implemented
  $eth_data = NetPacket::Ethernet::strip($raw_pkt);

DESCRIPTION

Top

NetPacket::Ethernet provides a set of routines for assembling and disassembling packets using the Ethernet protocol.

Methods

NetPacket::Ethernet->decode([RAW PACKET])

Decode the raw packet data given and return an object containing instance data. This method will quite happily decode garbage input. It is the responsibility of the programmer to ensure valid packet data is passed to this method.

NetPacket::Ethernet->encode(param => value)

Return an ethernet packet encoded with the instance data specified. Not implemented.

Functions

NetPacket::Ethernet::strip([RAW PACKET])

Return the encapsulated data (or payload) contained in the ethernet packet. This data is suitable to be used as input for other NetPacket::* modules.

This function is equivalent to creating an object using the decode() constructor and returning the data field of that object.

Instance data

The instance data for the NetPacket::Ethernet object consists of the following fields.

src_mac

The source MAC address for the ethernet packet as a hex string.

dest_mac

The destination MAC address for the ethernet packet as a hex string.

type

The protocol type for the ethernet packet.

data

The payload for the ethernet packet.

Exports

default

none

exportable

ETH_TYPE_IP ETH_TYPE_ARP ETH_TYPE_APPLETALK ETH_TYPE_SNMP ETH_TYPE_IPv6 ETH_TYPE_PPP

tags

The following tags group together related exportable items.

:types

ETH_TYPE_IP ETH_TYPE_ARP ETH_TYPE_APPLETALK ETH_TYPE_SNMP ETH_TYPE_IPv6 ETH_TYPE_PPP

:strip

Import the strip function eth_strip which is an alias for NetPacket::Ethernet::strip

:ALL

All the above exportable items.

EXAMPLE

Top

The following script dumps ethernet frames by mac address and protocol to standard output.

  #!/usr/bin/perl -w

  use strict;
  use Net::PcapUtils;
  use NetPacket::Ethernet;

  sub process_pkt {
      my($arg, $hdr, $pkt) = @_;

      my $eth_obj = NetPacket::Ethernet->decode($pkt);
      print("$eth_obj->{src_mac}:$eth_obj->{dest_mac} $eth_obj->{type}\n");
  }

  Net::PcapUtils::loop(\&process_pkt);

TODO

Top

Implement encode() function

COPYRIGHT

Top

Copyright (c) 2001 Tim Potter and Stephanie Wehner.

Copyright (c) 1995,1996,1997,1998,1999 ANU and CSIRO on behalf of the participants in the CRC for Advanced Computational Systems ('ACSys').

This module is free software. You can redistribute it and/or modify it under the terms of the Artistic License 2.0.

This program is distributed in the hope that it will be useful, but without any warranty; without even the implied warranty of merchantability or fitness for a particular purpose.

AUTHOR

Top

Tim Potter <tpot@samba.org>

NetPacket documentation Contained in the NetPacket distribution. 
package NetPacket::Ethernet;
BEGIN {
  $NetPacket::Ethernet::AUTHORITY = 'cpan:yanick';
}
BEGIN {
  $NetPacket::Ethernet::VERSION = '1.1.2';
}
# ABSTRACT: Assemble and disassemble ethernet packets.

use strict;
use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);

BEGIN {
    @ISA = qw(Exporter NetPacket);

    @EXPORT = qw();

    my @eth_types = qw/ ETH_TYPE_IP        
                        ETH_TYPE_ARP       
                        ETH_TYPE_APPLETALK 
                        ETH_TYPE_RARP      
                        ETH_TYPE_SNMP      
                        ETH_TYPE_IPv6      
                        ETH_TYPE_PPP       
                        ETH_TYPE_802_1Q    
                        ETH_TYPE_IPX       
                        ETH_TYPE_PPPOED    
                        ETH_TYPE_PPPOES    /;

    @EXPORT_OK = ( 'eth_strip', @eth_types ); 

    %EXPORT_TAGS = (
        ALL         => [@EXPORT, @EXPORT_OK],
        strip       => [qw(eth_strip)],
        types       => \@eth_types,
    );
}

#
# Partial list of ethernet protocol types from
# http://www.isi.edu/in-notes/iana/assignments/ethernet-numbers
#

use constant ETH_TYPE_IP        => 0x0800;
use constant ETH_TYPE_ARP       => 0x0806;
use constant ETH_TYPE_APPLETALK => 0x809b;
use constant ETH_TYPE_RARP      => 0x8035;
use constant ETH_TYPE_SNMP      => 0x814c;
use constant ETH_TYPE_IPv6      => 0x86dd;
use constant ETH_TYPE_PPP       => 0x880b;
use constant ETH_TYPE_802_1Q    => 0x8100;
use constant ETH_TYPE_IPX       => 0x8137;
use constant ETH_TYPE_PPPOED    => 0x8863;
use constant ETH_TYPE_PPPOES    => 0x8864;

#
# Decode the packet
#

sub decode {
    my $class = shift;
    my($pkt, $parent, @rest) = @_;
    my $self = {};

    # Class fields

    $self->{_parent} = $parent;
    $self->{_frame} = $pkt;

    # Decode ethernet packet

    if (defined($pkt)) {

	my($sm_lo, $sm_hi, $dm_lo, $dm_hi);

	($dm_hi, $dm_lo, $sm_hi, $sm_lo, $self->{type}, $self->{data}) = 
	    unpack('NnNnna*' , $pkt);

	# Convert MAC addresses to hex string to avoid representation
	# problems

	$self->{src_mac} = sprintf("%08x%04x", $sm_hi, $sm_lo);
	$self->{dest_mac} = sprintf("%08x%04x", $dm_hi, $dm_lo);
    }

    # Return a blessed object

    bless($self, $class);
    return $self;
}

#
# Strip header from packet and return the data contained in it
#

undef &eth_strip;        # Create eth_strip alias
*eth_strip = \&strip;

sub strip {
    my ($pkt, @rest) = @_;

    my $eth_obj = NetPacket::Ethernet->decode($pkt);
    return $eth_obj->{data};
}   

#
# Encode a packet - not implemented!
#

sub encode {
    die("Not implemented");
}

#
# Module initialisation
#

1;

# autoloaded methods go after the END token (&& pod) below





__END__


# any real autoloaded methods go after this line