Openview::Message::Sender - OO interface to sending HP OpenView messages.

   use Openview::Message::Sender; 
   my $ovs = new Openview::Message::Sender { application=>'name'
                             ,object=>'name'
                             ,text=>'msg_text"
                             ,group=>'msg_group'
                             ,host=>$ENV{'HOSTNAME'} 
                            };
   #take defaults from attributes of $ovs :
   $ovs->send( "your message text" ); 
   #or
   $ovs->send( text=>"your message text" ); 

   #providing call specific argments overriding the 
   #some of the defaults provided by the attributes of $ovs :
   $ovs->send( text=>"your message text" 
                   ,severity=>'minor' 
                   ,group=>'MsgGroup' [... etc]  );

package Openview::Message::Sender;

#use 5.6.0;
use strict;
use warnings;
require Exporter;

our @ISA = ( 'Exporter' );
our @EXPORT_OK = qw(
   OPC_SEV_NORMAL
   OPC_SEV_WARNING
   OPC_SEV_MINOR
   OPC_SEV_MAJOR
   OPC_SEV_CRITICAL
); 
our @EXPORT = ();
our $VERSION = '0.02';

use Openview::Message::opcmsg;

sub new
{
   die "Usage: expected at least one argument" if @_ < 1;
   my ( $class ,$ah ) = @_;
   my $self =  { application=>undef
                ,object=>undef
                ,text=>undef
                ,group=>undef
                ,host=>$ENV{'HOSTNAME'} 
                ,severity=>'unknown'
               };
   if ( ref $ah eq 'HASH' )
   {
      foreach my $key ( keys %$ah )
      {
         if ( not exists( $self->{$key} ) )
         {
            warn "Undefined attribute=$key in Openview::Message::new()" ;
            next;
         }
         else
         {
            $self->{$key} = $ah->{$key};
         }
      }
   }
   return bless $self ,$class;
}
sub send($;@)
{
   my $self = shift @_;
   #print "\@_=". join( "|" ,@_ )."\n" ; 
   my $h = {};
   if ( ! @_ )
   {
      $h->{'text'} = undef;
   }
   elsif ( @_ == 1 )
   {
      ( $h->{'text'} ) = @_;
   }
   else
   {
      %$h = @_;
   }
   opcmsg( $self->_severity( $h->{'severity'} )
          ,$self->_application( $h->{'application'} )
          ,$self->_object( $h->{'object'} )
          ,$self->_text( $h->{'text'} )
          ,$self->_group( $h->{'group'} )
          ,$self->_host( $h->{'host'} )
         ); 
}


sub _severity 
{ 
   my ($self,$sev ) = @_; 
   $sev = $self->{'severity'} if not defined $sev;
   return $sev if $sev =~ m/^\d+$/;
   return _str_to_severity($sev);
}
sub _value
{
   my ( $self ,$key ,$value ) = @_;
   return $value if defined $value;
   return defined $self->{$key} ? $self->{$key} : "$key not provided" ;
}
sub _application { my $s = shift @_; $s->_value( 'application' ,@_ ); }
sub _object      { my $s = shift @_; $s->_value( 'object'      ,@_ ); }
sub _text        { my $s = shift @_; $s->_value( 'text'        ,@_ ); }
sub _group       { my $s = shift @_; $s->_value( 'group'       ,@_ ); }
sub _host        { my $s = shift @_; $s->_value( 'host'        ,@_ ); }

#my $_sevmap = {
#       'normal'    => OPC_SEV_NORMAL()
#      ,'warning'   => OPC_SEV_WARNING()
#      ,'minor'     => OPC_SEV_MINOR()
#      ,'major'     => OPC_SEV_MAJOR()
#      ,'critical'  => OPC_SEV_CRITICAL()
#      #,'unknown'   => OPC_SEV_UNKNOWN()
#      #,'unchanged' => OPC_SEV_UNCHANGED()
#      #,'none'      => OPC_SEV_NONE()
#   };

sub _str_to_severity
{
   my $str = shift @_;
   return OPC_SEV_NORMAL() if ( $str eq 'normal' );
   return OPC_SEV_WARNING() if ( $str eq 'warning' );
   return OPC_SEV_MINOR() if ( $str eq 'minor' );
   return OPC_SEV_MAJOR() if ( $str eq 'major' );
   return OPC_SEV_CRITICAL() if ( $str eq 'critical' );
   die( "Undefined severity=$str" );
}

1;
__END__