PPI::Statement::Include - Statements that include other code

PPI documentation Contained in the PPI distribution.

Index

Code Index:

NAME

Top

PPI::Statement::Include - Statements that include other code

SYNOPSIS

Top

  # The following are all includes
  use 5.006;
  use strict;
  use My::Module;
  use constant FOO => 'Foo';
  require Foo::Bar;
  require "Foo/Bar.pm";
  require $foo if 1;
  no strict 'refs';

INHERITANCE

Top

  PPI::Statement::Include
  isa PPI::Statement
      isa PPI::Node
          isa PPI::Element

DESCRIPTION

Top

Despite its name, the PPI::Statement::Include class covers a number of different types of statement that cover all statements starting with use, no and require.

But basically, they cover three situations.

Firstly, a dependency on a particular version of perl (for which the version method returns true), a pragma (for which the pragma method returns true, or the loading (and unloading via no) of modules.

METHODS

Top

PPI::Statement::Include has a number of methods in addition to the standard PPI::Statement, PPI::Node and PPI::Element methods.

type

The type method returns the general type of statement ('use', 'no' or 'require').

Returns the type as a string, or undef if the type cannot be detected.

module

The module method returns the module name specified in any include statement. This includes pragma names, because pragma are implemented as modules. (And lets face it, the definition of a pragma can be fuzzy at the best of times in any case)

This covers all of these...

  use strict;
  use My::Module;
  no strict;
  require My::Module;

...but does not cover any of these...

  use 5.006;
  require 5.005;
  require "explicit/file/name.pl";

Returns the module name as a string, or undef if the include does not specify a module name.

module_version

The module_version method returns the minimum version of the module required by the statement, if there is one.

pragma

The pragma method checks for an include statement's use as a pragma, and returns it if so.

Or at least, it claims to. In practice it's a lot harder to say exactly what is or isn't a pragma, because the definition is fuzzy.

The intent of a pragma is to modify the way in which the parser works. This is done though the use of modules that do various types of internals magic.

For now, PPI assumes that any "module name" that is only a set of lowercase letters (and perhaps numbers, like use utf8;). This behaviour is expected to change, most likely to something that knows the specific names of the various "pragmas".

Returns the name of the pragma, or false ('') if the include is not a pragma.

version

The version method checks for an include statement that introduces a dependency on the version of perl the code is compatible with.

This covers two specific statements.

  use 5.006;
  require 5.006;

Currently the version is returned as a string, although in future the version may be returned as a version object. If you want a numeric representation, use version_literal(). Returns false if the statement is not a version dependency.

version_literal

The version_literal method has the same behavior as version(), but the version is returned as a numeric literal. Returns false if the statement is not a version dependency.

The arguments method gives you the rest of the statement after the the module/pragma and module version, i.e. the stuff that will be used to construct what gets passed to the module's import() subroutine. This does include the comma, etc. operators, but doesn't include non-significant direct children or any final semicolon.

TO DO

Top

- Write specific unit tests for this package

SUPPORT

Top

See the support section in the main module.

AUTHOR

Top

Adam Kennedy <adamk@cpan.org>

COPYRIGHT

Top

Copyright 2001 - 2011 Adam Kennedy.

This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

The full text of the license can be found in the LICENSE file included with this module.

PPI documentation Contained in the PPI distribution. 
package PPI::Statement::Include;


use strict;
use PPI::Statement                 ();
use PPI::Statement::Include::Perl6 ();

use vars qw{$VERSION @ISA};
BEGIN {
	$VERSION = '1.215';
	@ISA     = 'PPI::Statement';
}


sub type {
	my $self    = shift;
	my $keyword = $self->schild(0) or return undef;
	$keyword->isa('PPI::Token::Word') and $keyword->content;
}


sub module {
	my $self = shift;
	my $module = $self->schild(1) or return undef;
	$module->isa('PPI::Token::Word') and $module->content;
}


sub module_version {
	my $self     = shift;
	my $argument = $self->schild(3);
	if ( $argument and $argument->isa('PPI::Token::Operator') ) {
		return undef;
	}

	my $version = $self->schild(2) or return undef;
	return undef unless $version->isa('PPI::Token::Number');

	return $version;
}


sub pragma {
	my $self   = shift;
	my $module = $self->module or return '';
	$module =~ /^[a-z][a-z\d]*$/ ? $module : '';
}


sub version {
	my $self    = shift;
	my $version = $self->schild(1) or return undef;
	$version->isa('PPI::Token::Number') ? $version->content : '';
}


sub version_literal {
	my $self    = shift;
	my $version = $self->schild(1) or return undef;
	$version->isa('PPI::Token::Number') ? $version->literal : '';
}


sub arguments {
	my $self = shift;
	my @args = $self->schildren;

	# Remove the "use", "no" or "require"
	shift @args;

	# Remove the statement terminator
	if (
		$args[-1]->isa('PPI::Token::Structure')
		and
		$args[-1]->content eq ';'
	) {
		pop @args;
	}

	# Remove the module or perl version.
	shift @args;  

	return unless @args;

	if ( $args[0]->isa('PPI::Token::Number') ) {
		my $after = $args[1] or return;
		$after->isa('PPI::Token::Operator') or shift @args;
	}

	return @args;
}

1;