PPI::Token::Pod - Sections of POD in Perl documents

PPI documentation Contained in the PPI distribution.

Index

Code Index:

NAME

Top

PPI::Token::Pod - Sections of POD in Perl documents

INHERITANCE

Top

  PPI::Token::Pod
  isa PPI::Token
      isa PPI::Element

DESCRIPTION

Top

A single PPI::Token::Pod object represents a complete section of POD documentation within a Perl document.

METHODS

Top

This class provides some additional methods beyond those provided by its PPI::Token and PPI::Element parent classes.

Got any ideas for more methods? Submit a report to rt.cpan.org!

merge @podtokens

The merge constructor takes a number of PPI::Token::Pod objects, and returns a new object that represents one combined POD block with the content of all of them.

Returns a new PPI::Token::Pod object, or undef on error.

lines

The lines method takes the string of POD and breaks it into lines, returning them as a list.

SUPPORT

Top

See the support section in the main module.

AUTHOR

Top

Adam Kennedy <adamk@cpan.org>

COPYRIGHT

Top

Copyright 2001 - 2011 Adam Kennedy.

This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

The full text of the license can be found in the LICENSE file included with this module.

PPI documentation Contained in the PPI distribution. 
package PPI::Token::Pod;


use strict;
use Params::Util qw{_INSTANCE};
use PPI::Token   ();

use vars qw{$VERSION @ISA};
BEGIN {
	$VERSION = '1.215';
	@ISA     = 'PPI::Token';
}





#####################################################################
# PPI::Token::Pod Methods


sub merge {
	my $class = (! ref $_[0]) ? shift : return undef;

	# Check there are no bad arguments
	if ( grep { ! _INSTANCE($_, 'PPI::Token::Pod') } @_ ) {
		return undef;
	}

	# Get the tokens, and extract the lines
	my @content = ( map { [ $_->lines ] } @_ ) or return undef;

	# Remove the leading =pod tags, trailing =cut tags, and any empty lines
	# between them and the pod contents.
	foreach my $pod ( @content ) {
		# Leading =pod tag
		if ( @$pod and $pod->[0] =~ /^=pod\b/o ) {
			shift @$pod;
		}

		# Trailing =cut tag
		if ( @$pod and $pod->[-1] =~ /^=cut\b/o ) {
			pop @$pod;
		}

		# Leading and trailing empty lines
		while ( @$pod and $pod->[0]  eq '' ) { shift @$pod }
		while ( @$pod and $pod->[-1] eq '' ) { pop @$pod   }
	}

	# Remove any empty pod sections, and add the =pod and =cut tags
	# for the merged pod back to it.
	@content = ( [ '=pod' ], grep { @$_ } @content, [ '=cut' ] );

	# Create the new object
	$class->new( join "\n", map { join( "\n", @$_ ) . "\n" } @content );
}


sub lines {
	split /(?:\015{1,2}\012|\015|\012)/, $_[0]->{content};
}






#####################################################################
# PPI::Element Methods

### XS -> PPI/XS.xs:_PPI_Token_Pod__significant 0.900+
sub significant { '' }





#####################################################################
# Tokenizer Methods

sub __TOKENIZER__on_line_start {
	my $t = $_[1];

	# Add the line to the token first
	$t->{token}->{content} .= $t->{line};

	# Check the line to see if it is a =cut line
	if ( $t->{line} =~ /^=(\w+)/ ) {
		# End of the token
		$t->_finalize_token if lc $1 eq 'cut';
	}

	0;
}

1;