Package::Reaper - pseudo-garbage-collection for packages

Package-Generator documentation Contained in the Package-Generator distribution.

Index

Code Index:

NAME

Top

Package::Reaper - pseudo-garbage-collection for packages

VERSION

Top

version 0.103

SYNOPSIS

Top

    use Package::Generator;
    use Package::Reaper;

    {
      my $package = Package::Generator->new_package;
      my $reaper  = Package::Reaper->new($package);
      ...
    }

    # at this point, $package stash has been deleted

DESCRIPTION

Top

This module allows you to create simple objects which, when destroyed, delete a given package. This lets you approximate lexically scoped packages.

INTERFACE

Top

new

  my $reaper = Package::Reaper->new($package);

This returns the newly generated package reaper. When the reaper goes out of scope and is garbage collected, it will delete the symbol table entry for the package.

package

  my $package = $reaper->package;

This method returns the package which will be reaped.

is_armed

  if ($reaper->is_armed) { ... }

This method returns true if the reaper is armed and false otherwise. Reapers always start out armed. A disarmed reaper will not actually reap when destroyed.

disarm

  $reaper->disarm;

This method disarms the reaper, so that it will not reap the package when it is destoryed.

arm

  $reaper->arm;

This method arms the reaper, so that it will reap its package when it is destroyed. By default, new reapers are armed.

AUTHOR

Top

Ricardo SIGNES, <rjbs@cpan.org>

BUGS

Top

Please report any bugs or feature requests to bug-package-generator@rt.cpan.org, or through the web interface at http://rt.cpan.org. I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.

COPYRIGHT

Top

Copyright 2006 Ricardo Signes, all rights reserved.

This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

Package-Generator documentation Contained in the Package-Generator distribution. 
package Package::Reaper;
use 5.008;
use warnings;
use strict;

use Carp ();
use Symbol ();


our $VERSION = '0.103';


sub new {
  my ($class, $package) = @_;

  # Do I care about checking $package with _CLASS and/or exists_package?
  # Probably not, for now. -- rjbs, 2006-06-05
  my $self = [ $package, 1 ];
  bless $self => $class;
}


sub package {
  my $self = shift;
  Carp::croak "a reaper's package may not be altered" if @_;
  return $self->[0];
}


sub is_armed {
  my $self = shift;
  return $self->[1] == 1;
}


sub disarm { $_[0]->[1] = 0 }


sub arm { $_[0]->[1] = 1 }

sub DESTROY {
  my ($self) = @_;

  return unless $self->is_armed;

  my $package = $self->package;

  Symbol::delete_package($package);
}


"You might be a king or a little street sweeper, but sooner or later you dance
with Package:Reaper.";