Parse::CPAN::Ratings - Parse CPAN ratings

  my $ratings
      = Parse::CPAN::Ratings->new( filename => 't/all_ratings_100.csv' );

  my $rating = $ratings->rating('Archive-Zip');
  print $rating->distribution . "\n"; # Archive-Zip
  print $rating->rating . "\n";       # 3.8
  print $rating->review_count . "\n"; # 6

  my @all_ratings = $ratings->ratings;

  http://cpanratings.perl.org/

  http://cpanratings.perl.org/csv/all_ratings.csv

  my $rating = $ratings->rating('Archive-Zip');
  print $rating->distribution . "\n"; # Archive-Zip
  print $rating->rating . "\n";       # 3.8
  print $rating->review_count . "\n"; # 6

  my @all_ratings = $ratings->ratings;

package Parse::CPAN::Ratings;
use Moose;
use MooseX::StrictConstructor;
use MooseX::Types::Path::Class;
use Parse::CPAN::Ratings::Rating;
use Parse::CSV;
our $VERSION = '0.33';

has 'filename' =>
    ( is => 'ro', isa => 'Path::Class::File', required => 1, coerce => 1 );

has 'db' => (
    is         => 'ro',
    isa        => 'HashRef[Parse::CPAN::Ratings::Rating]',
    lazy_build => 1,
);

no Moose;

__PACKAGE__->meta->make_immutable;

sub _build_db {
    my $self     = shift;
    my $filename = $self->filename;
    my %db;

    my $parser = Parse::CSV->new(
        file   => $filename->stringify,
        fields => 'auto',
    );
    while ( my $rating = $parser->fetch ) {
        $db{ $rating->{distribution} } = Parse::CPAN::Ratings::Rating->new(
            distribution => $rating->{distribution},
            rating       => $rating->{rating},
            review_count => $rating->{review_count},
        );
    }
    if ( $parser->errstr ) {
        confess( "Error parsing CSV: " . $parser->errstr );
    }
    return \%db;
}

sub rating {
    my ( $self, $distribution ) = @_;
    return $self->db->{$distribution};
}

sub ratings {
    my $self = shift;
    return values %{ $self->db };
}

__END__