Perl::Critic::Policy::ValuesAndExpressions::ProhibitSpecialLiteralHeredocTerminator - Don't write C< print <<'__END__' >.

Perl-Critic documentation Contained in the Perl-Critic distribution.

Index

Code Index:

NAME

Top

Perl::Critic::Policy::ValuesAndExpressions::ProhibitSpecialLiteralHeredocTerminator - Don't write print <<'__END__' .

AFFILIATION

Top

This Policy is part of the core Perl::Critic distribution.

DESCRIPTION

Top

Using one of Perl's special literals as a HEREDOC terminator could be confusing to tools that try to parse perl.

    print <<'__END__';           #not ok
    Hello world
    __END__

    print <<'__END_OF_WORLD__';  #ok
    Goodbye world!
    __END_OF_WORLD__

The special literals that this policy prohibits are:

__END__
__DATA__
__PACKAGE__
__FILE__
__LINE__

CONFIGURATION

Top

This Policy is not configurable except for the standard options.

SEE ALSO

Top

Perl::Critic::Policy::ValuesAndExpressions::RequireUpperCaseHeredocTerminator

Perl::Critic::Policy::ValuesAndExpressions::RequireQuotedHeredocTerminator

AUTHOR

Top

Kyle Hasselbacher <kyle@cpan.org>

COPYRIGHT

Top

Copyright (c) 2009-2011 Kyle Hasselbacher.

This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself. The full text of this license can be found in the LICENSE file included with this module.

Perl-Critic documentation Contained in the Perl-Critic distribution. 
##############################################################################
#      $URL: http://perlcritic.tigris.org/svn/perlcritic/trunk/distributions/Perl-Critic/lib/Perl/Critic/Policy/ValuesAndExpressions/ProhibitSpecialLiteralHeredocTerminator.pm $
#     $Date: 2011-05-15 16:34:46 -0500 (Sun, 15 May 2011) $
#   $Author: clonezone $
# $Revision: 4078 $
##############################################################################

package Perl::Critic::Policy::ValuesAndExpressions::ProhibitSpecialLiteralHeredocTerminator;

use 5.006001;
use strict;
use warnings;

use Readonly;

use Perl::Critic::Utils qw{ :severities };
use base 'Perl::Critic::Policy';

our $VERSION = '1.116';

#-----------------------------------------------------------------------------

Readonly::Hash my %SPECIAL_LITERAL => map { '__' . $_ . '__' => 1 }
                                      qw( FILE LINE PACKAGE END DATA );
Readonly::Scalar my $DESC =>
    q{Heredoc terminator must not be a special literal};

#-----------------------------------------------------------------------------

sub supported_parameters { return ()                       }
sub default_severity     { return $SEVERITY_MEDIUM         }
sub default_themes       { return qw(core maintenance)     }
sub applies_to           { return 'PPI::Token::HereDoc'    }

#-----------------------------------------------------------------------------

sub violates {
    my ( $self, $elem, undef ) = @_;

    # remove << and (optional) quotes from around terminator
    ( my $heredoc_terminator = $elem ) =~
        s{ \A << \s* (["']?) (.*) \1 \z }{$2}xms;

    if ( $SPECIAL_LITERAL{ $heredoc_terminator } ) {
        my $expl = qq{Used "$heredoc_terminator" as heredoc terminator};
        return $self->violation( $DESC, $expl, $elem );
    }

    return;    #ok!
}

1;

__END__

#-----------------------------------------------------------------------------


# Local Variables:
#   mode: cperl
#   cperl-indent-level: 4
#   fill-column: 78
#   indent-tabs-mode: nil
#   c-indentation-style: bsd
# End:
# ex: set ts=8 sts=4 sw=4 tw=78 ft=perl expandtab shiftround :