Perl::Dist::WiX::IconArray - A list of <Icon> tags.

	# Create an icon array
	my $array = Perl::Dist::WiX::IconArray->new();

	# Add an icon to the array, then go looking for it.
	my $icon_id = $array->add_icon('C:\strawberry\win32\cpan.ico', 'C:\strawberry\perl\bin\cpan.bat');
	$icon_id = $array->search_icon('C:\strawberry\win32\cpan.ico', 'bat');

	# The second parameters are optional IF you're referring to the msi's icon.
	my $icon_id_2 = $array->add_icon('C:\strawberry\win32\strawberry.ico');
	$icon_id_2 = $array->search_icon('C:\strawberry\win32\strawberry.ico');

	# Print out all the icons in XML format.
	my $xml = $array->as_string();

	my $array = Perl::Dist::WiX::IconArray->new();

	my $icon_id = $array->add_icon('C:\strawberry\win32\cpan.ico', 'C:\strawberry\perl\bin\cpan.bat');

	my $icon_id = $array->search_icon('C:\strawberry\win32\cpan.ico', 'bat');

	my $xml = $array->as_string();

package Perl::Dist::WiX::IconArray;

use 5.010;
use Moose 0.90;
use Params::Util qw( _STRING _INSTANCE  );
use File::Spec::Functions qw( splitpath );
require Perl::Dist::WiX::Tag::Icon;

with 'WiX3::Role::Traceable';

our $VERSION = '1.500';
$VERSION =~ s/_//ms;

# Private storage for the icons added.
has _icon => (
	traits   => ['Array'],
	is       => 'rw',
	isa      => 'ArrayRef[Perl::Dist::WiX::Tag::Icon]',
	default  => sub { [] },
	init_arg => undef,
	handles  => {
		'_push_icon'      => 'push',
		'_count_icons'    => 'count',
		'_get_icon_array' => 'elements',
	},
);

sub add_icon {
	my ( $self, $pathname_icon, $pathname_target ) = @_;

	# Check parameters
	if ( not defined $pathname_target ) {
		$pathname_target = 'Perl.msi';
	}
	if ( defined _INSTANCE( $pathname_icon, 'Path::Class::File' ) ) {
		$pathname_icon = $pathname_icon->stringify();
	}
	if ( defined _INSTANCE( $pathname_target, 'Path::Class::File' ) ) {
		$pathname_target = $pathname_target->stringify();
	}
	if ( not defined _STRING($pathname_target) ) {
		PDWiX::Parameter->throw(
			parameter => 'pathname_target',
			where     => '::IconArray->add_icon'
		);
	}
	if ( not defined _STRING($pathname_icon) ) {
		PDWiX::Parameter->throw(
			parameter => 'pathname_icon',
			where     => '::IconArray->add_icon'
		);
	}

	# Find the type of target.
	my ($target_type) = $pathname_target =~ m{\A.*[.](.+)\z}msx;

	$self->trace_line( 2,
		"Adding icon $pathname_icon with target type $target_type.\n" );

	# If we have an icon already, return it.
	my $icon = $self->search_icon( $pathname_icon, $target_type );
	if ( defined $icon ) { return $icon; }

	# Get Id made.
	my ( undef, undef, $filename_icon ) = splitpath($pathname_icon);
	my $id = substr $filename_icon, 0, -4;
	$id =~ s/[[:^alnum:]]/_/gmxs;      # Substitute _ for anything
	                                   # non-alphanumeric.
	$id .= ".$target_type.ico";

	# Add icon to our list.
	$self->_push_icon(
		Perl::Dist::WiX::Tag::Icon->new(
			sourcefile  => $pathname_icon,
			target_type => $target_type,
			id          => $id
		) );

	return $id;
} ## end sub add_icon

sub search_icon {
	## no critic (ProhibitExplicitReturnUndef)
	my ( $self, $pathname_icon, $target_type ) = @_;

	# Check parameters
	if ( not defined $target_type ) {
		$target_type = 'msi';
	}
	if ( not defined _STRING($target_type) ) {
		PDWiX::Parameter->throw(
			parameter => 'target_type',
			where     => '::IconArray->search_icon'
		);
	}
	if ( not defined _STRING($pathname_icon) ) {
		PDWiX::Parameter->throw(
			parameter => 'pathname_icon',
			where     => '::IconArray->search_icon'
		);
	}

	if ( 0 == $self->_count_icons() ) { return undef; }

	# Print each icon
	foreach my $icon ( $self->_get_icon_array() ) {
		if (    ( $icon->get_sourcefile eq $pathname_icon )
			and ( $icon->get_target_type eq $target_type ) )
		{
			return $icon->get_id;
		}
	}

	return undef;
} ## end sub search_icon

sub as_string {
	my $self = shift;
	my $answer;

	# Short-circuit
	if ( 0 == $self->_count_icons ) { return q{}; }

	# Print each icon
	foreach my $icon ( $self->_get_icon_array() ) {
		my $id   = $icon->get_id();
		my $file = $icon->get_sourcefile();
		$answer .= "    <Icon Id='I_$id' SourceFile='$file' />\n";
	}

	return $answer;
} ## end sub as_string

no Moose;
__PACKAGE__->meta->make_immutable;

1;

__END__