Plack::Middleware::LighttpdScriptNameFix - fixes wrong SCRIPT_NAME and PATH_INFO that lighttpd sets

Plack documentation Contained in the Plack distribution.

Index

Code Index:

NAME

Top

Plack::Middleware::LighttpdScriptNameFix - fixes wrong SCRIPT_NAME and PATH_INFO that lighttpd sets

SYNOPSIS

Top

  # in your app.psgi
  use Plack::Builder;

  builder {
    enable "LighttpdScriptNameFix";
    $app;
  };

  # Or from the command line
  plackup -s FCGI -e 'enable "LighttpdScriptNameFix"' /path/to/app.psgi

DESCRIPTION

Top

This middleware fixes wrong SCRIPT_NAME and PATH_INFO set by lighttpd when you mount your app under the root path ("/"). If you use lighttpd 1.4.23 or later you can instead enable fix-root-scriptname flag inside fastcgi.server instead of using this middleware.

CONFIGURATION

Top

script_name

Even with fix-root-scriptname, lighttpd still sets weird SCRIPT_NAME and PATH_INFO if you mount your application at "" or something that ends with /. Setting script_name option tells the middleware how to reconstruct the new correct SCRIPT_NAME and PATH_INFO.

If you mount the app under /something/, you should set:

  enable "LighttpdScriptNameFix", script_name => "/something";

and when a request for /something/a/b?param=1 comes, SCRIPT_NAME becomes /something and PATH_INFO becomes /a/b.

script_name option is set to empty by default, which means all the request path is set to PATH_INFO and it behaves like your fastcgi application is mounted in the root path.

AUTHORS

Top

Yury Zavarin

Tatsuhiko Miyagawa

SEE ALSO

Top

Plack::Handler::FCGI http://github.com/miyagawa/Plack/issues#issue/68 https://redmine.lighttpd.net/issues/729

Plack documentation Contained in the Plack distribution. 
package Plack::Middleware::LighttpdScriptNameFix;
use strict;
use parent qw/Plack::Middleware/;
use Plack::Util::Accessor qw(script_name);

sub prepare_app {
    my $self = shift;

    my $script_name = $self->script_name;
    $script_name = '' unless defined($script_name);
    $script_name =~ s!/$!!;
    $self->script_name($script_name);
}

sub call {
    my($self, $env) = @_;

    if ($env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ /lighttpd/) {
        $env->{PATH_INFO}   = $env->{SCRIPT_NAME} . $env->{PATH_INFO};
        $env->{SCRIPT_NAME} = $self->script_name;
        $env->{PATH_INFO}  =~ s/^\Q$env->{SCRIPT_NAME}\E//;
    }

    return $self->app->($env);
}

1;

__END__