Plack::Middleware::LogDispatch - Uses Log::Dispatch to configure logger

Plack documentation Contained in the Plack distribution.

Index

Code Index:

NAME

Top

Plack::Middleware::LogDispatch - Uses Log::Dispatch to configure logger

SYNOPSIS

Top

  use Log::Dispatch;

  my $logger = Log::Dispatch->new;
  $logger->add( Log::Dispatch::File->new(...) );
  $logger->add( Log::Dispatch::DesktopNotification->new(...) );

  builder {
      enable "LogDispatch", logger => $logger;
      $app;
  }

  # use with Log::Dispatch::Config
  use Log::Dispatch::Config;
  Log::Dispatch::Config->configure('/path/to/log.conf');

  builder {
      enable "LogDispatch", logger => Log::Dispatch::Config->instance;
      ...
  }

DESCRIPTION

Top

LogDispatch is a Plack::Middleware component that allows you to use Log::Dispatch to configure logging object.

CONFIGURATION

Top

logger

Log::Dispatch object to send logs to. Required.

AUTHOR

Top

Tatsuhiko Miyagawa

SEE ALSO

Top

Log::Dispatch

Plack documentation Contained in the Plack distribution. 
package Plack::Middleware::LogDispatch;
use strict;
use parent qw(Plack::Middleware);
use Plack::Util::Accessor qw(logger);
use Carp ();

sub prepare_app {
    my $self = shift;
    unless ($self->logger) {
        Carp::croak "logger is not defined";
    }
}

sub call {
    my($self, $env) = @_;

    $env->{'psgix.logger'} = sub {
        my $args = shift;
        $args->{level} = 'critical' if $args->{level} eq 'fatal';
        $self->logger->log(%$args);
    };

    $self->app->($env);
}

1;

__END__