Plack::Test - Test PSGI applications with various backends

  use Plack::Test;

  # named params
  test_psgi
      app => sub {
          my $env = shift;
          return [ 200, [ 'Content-Type' => 'text/plain' ], [ "Hello World" ] ],
      },
      client => sub {
          my $cb = shift;
          my $req = HTTP::Request->new(GET => "http://localhost/hello");
          my $res = $cb->($req);
          like $res->content, qr/Hello World/;
      };

   use HTTP::Request::Common;

   # positional params (app, client)
   my $app = sub { return [ 200, [], [ "Hello "] ] };
   test_psgi $app, sub {
       my $cb = shift;
       my $res = $cb->(GET "/");
       is $res->content, "Hello";
   };

Plack::Test is a unified interface to test PSGI applications using standard HTTP::Request and HTTP::Response objects. It also allows you to run PSGI applications in various ways, by default using MockHTTP backend but can also use Server backend, which uses one of Plack::Handler implementations to run the web server to do live HTTP requests.

test_psgi

  test_psgi $app, $client;
  test_psgi app => $app, client => $client;

Runs the client test code $client against a PSGI application $app. The client callback gets one argument $cb, that is a callback that accepts an HTTP::Request object and returns an HTTP::Response object.

For the convenience, HTTP::Request given to the callback is automatically adjusted to the correct protocol (http) and host names (127.0.0.1 by default), so the following code just works.

  use HTTP::Request::Common;
  test_psgi $app, sub {
      my $cb = shift;
      my $res = $cb->(GET "/hello");
  };

Note that however, it is not a good idea to pass an arbitrary (i.e. user-input) string to the GET function or even HTTP::Request->new by assuming that it always represents a path, because:

  my $req = GET "//foo/bar";

would represent a request for a URL that has no scheme, has a hostname foo and a path /bar, instead of a path //foo/bar which you might actually want.

You can specify the Plack::Test backend using the environment variable PLACK_TEST_IMPL or $Plack::Test::Impl package variable.

The available values for the backend are:

MockHTTP

(Default) Creates a PSGI env hash out of HTTP::Request object, runs the PSGI application in-process and returns HTTP::Response.

Server

Runs one of Plack::Handler backends (Standalone by default) and sends live HTTP requests to test.

ExternalServer

Runs tests against an external server specified in the PLACK_TEST_EXTERNALSERVER_URI environment variable instead of spawning the application in a server locally.

For instance, you can test your application with ServerSimple server backends with:

  > env PLACK_TEST_IMPL=Server PLACK_SERVER=ServerSimple prove -l t/test.t

Tatsuhiko Miyagawa