Plucene::Index::SegmentInfos - A collection of SegmentInfo objects

Plucene documentation Contained in the Plucene distribution.

Index

Code Index:

NAME

Top

Plucene::Index::SegmentInfos - A collection of SegmentInfo objects

SYNOPSIS

Top

	my $segmentinfos = Plucene::Index::SegmentInfos->new;

	$segmentinfos->read($dir);
	$segmentinfos->write($dir);

	$segmentinfos->add_element(Plucene::Index::SegmentInfo $segment_info);

	my Plucene::Index::SegmentInfo @segment_info 
		= $segmentinfos->segments;

DESCRIPTION

Top

This is a collection of Plucene::Index::SegmentInfo objects

METHODS

Top

new

	my $segmentinfos = Plucene::Index::SegmentInfos->new;

This will create a new (empty) Plucene::Index::SegmentInfos object.

read

	$segmentinfos->read($dir);

This will read the segments file from the passed directory.

write

	$segmentinfos->write($dir);

This will write the segments info file out.

add_element

	$segmentinfos->add_element(Plucene::Index::SegmentInfo $segment_info);

This will add the passed Plucene::Index::SegmentInfo object..

info

	my Plucene::Index::SegmentInfo $info 
		= $segmentinfos->info($segment_no);

This will return the Plucene::Index::SegmentInfo object at the passed segment number.

segments

	my Plucene::Index::SegmentInfo @segment_info 
		= $segmentinfos->segments;

This returns all the Plucene::Index::SegmentInfo onjects in this segment.

Plucene documentation Contained in the Plucene distribution. 
package Plucene::Index::SegmentInfos;


use strict;
use warnings;

use Carp;

use Plucene::Index::SegmentInfo;
use Plucene::Store::InputStream;
use Plucene::Store::OutputStream;
use File::Slurp;


sub new { bless { segments => [] }, shift }


sub read {
	my ($self, $directory) = @_;
	my ($count, @unpack) = unpack "NN/(w/aN)", read_file("$directory/segments");
	my @segs;
	while (my ($name, $count) = splice @unpack, 0, 2) {
		push @segs,
			bless {
			name      => $name,
			doc_count => $count,
			dir       => $directory,
			} => 'Plucene::Index::SegmentInfo';
	}
	$self->{segments} = \@segs;
	$self->{counter}  = $count;
}


sub write {
	my ($self, $directory) = @_;
	my $segfile  = "$directory/segments";
	my $tempfile = "${segfile}.new";
	my @segs     = $self->segments;
	my $template = "NN" . ("w/a*N" x @segs);
	my $packed   = pack $template, $self->{counter} || 0, scalar @segs,
		map { $_->name => $_->doc_count } @segs;
	write_file($tempfile => $packed);
	rename($tempfile => $segfile);
}


sub add_element { push @{ $_[0]->{segments} }, $_[1] }


sub info { $_[0]->{segments}->[ $_[1] ] }


sub segments { @{ $_[0]->{segments} } }

1;